Quality Measure Implementation Guide
2.0.0-ballot - STU 2 Ballot

Quality Measure Implementation Guide - Downloaded Version null See the Directory of published versions

## Library: EXM125 - Breast Cancer Screening Library (Experimental)

Official URL: http://hl7.org/fhir/uv/cqm/Library/EXM125 | Version: 8.0.000 | Highlight text changes?
Standards status: Informative Active as of 2019-09-03 | Computable Name: EXM125
Other Identifiers: http://example.org/fhir/cqi/ecqm/Library/Identifier#EXM125 (use: official, ), OID:2.16.840.1.113883.4.642.40.61.28.10

This library is used as an example in the FHIR Quality Measure Implementation Guide

Metadata
Title | EXM125 - Breast Cancer Screening Library
Version | 8.0.000
Identifier | EXM125
Identifier | urn:oid:2.16.840.1.113883.4.642.40.61.28.10
Approval Date | 2019-08-03
Last Review Date | 2019-08-03
Experimental | true
Jurisdiction | 001 from http://unstats.un.org/unsd/methods/m49/m49.htm
Topic | FHIR
Topic | CQL
Steward (Publisher) | HL7 International / Clinical Quality Information
Description | This library is used as an example in the FHIR Quality Measure Implementation Guide
Type | logic-library from http://terminology.hl7.org/CodeSystem/library-type
Dependency | Description: Library FHIRHelpers Resource: http://hl7.org/fhir/uv/cql/Library/FHIRHelpers|4.0.1 Canonical URL: `http://hl7.org/fhir/uv/cql/Library/FHIRHelpers|4.0.1`
Dependency | Description: Library Hospice Resource: Hospice FHIR Libraryversion: null2.0.000) Canonical URL: `http://hl7.org/fhir/uv/cqm/Library/Hospice|2.0.000`
Dependency | Description: Library AdultOutpatientEncounters Resource: Adult Outpatient Encounters Common Libraryversion: null2.0.000) Canonical URL: `http://hl7.org/fhir/uv/cqm/Library/AdultOutpatientEncounters|2.0.000`
Dependency | Description: Library Global Resource: MAT Global Common Functions FHIR Libraryversion: null5.0.000) Canonical URL: `http://hl7.org/fhir/uv/cqm/Library/MATGlobalCommonFunctions|5.0.000`
Dependency | Description: Library SDE Resource: Supplemental Data Elementsversion: null2.0.000) Canonical URL: `http://hl7.org/fhir/uv/cqm/Library/SupplementalDataElements|2.0.000`
Dependency | Description: Value Set ONC Administrative Sex Resource: ONC Administrative Sex Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1`
Dependency | Description: Value Set Race Resource: Race Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.836`
Dependency | Description: Value Set Ethnicity Resource: Ethnicity Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.837`
Dependency | Description: Value Set Payer Resource: Payer Type Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.3591`
Dependency | Description: Value Set Bilateral Mastectomy Resource: Bilateral Mastectomy Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1005`
Dependency | Description: Value Set Female Resource: Female Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.560.100.2`
Dependency | Description: Value Set Mammography Resource: Mammography Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1018`
Dependency | Description: Value Set Unilateral Mastectomy Resource: Unilateral Mastectomy Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1020`
Dependency | Description: Value Set History of bilateral mastectomy Resource: History of bilateral mastectomy Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1068`
Dependency | Description: Value Set Status Post Left Mastectomy Resource: Status Post Left Mastectomy Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1069`
Dependency | Description: Value Set Status Post Right Mastectomy Resource: Status Post Right Mastectomy Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1070`
Dependency | Description: Value Set Left Resource: Left Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.122.12.1036`
Dependency | Description: Value Set Right Resource: Right Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.122.12.1035`
Dependency | Description: Value Set Unilateral Mastectomy, Unspecified Laterality Resource: Unilateral Mastectomy, Unspecified Laterality Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1071`
Data Requirement | Type: Procedure Profile(s): Procedure Code Filter(s): Path: code ValueSet: Unilateral Mastectomy
Data Requirement | Type: Condition Profile(s): Condition Code Filter(s): Path: code ValueSet: Status Post Right Mastectomy
Data Requirement | Type: Condition Profile(s): Condition Code Filter(s): Path: code ValueSet: Status Post Left Mastectomy
Data Requirement | Type: Condition Profile(s): Condition Code Filter(s): Path: code ValueSet: Unilateral Mastectomy, Unspecified Laterality
Data Requirement | Type: Condition Profile(s): Condition Code Filter(s): Path: code ValueSet: History of bilateral mastectomy
Data Requirement | Type: Procedure Profile(s): Procedure Code Filter(s): Path: code ValueSet: Bilateral Mastectomy
Data Requirement | Type: DiagnosticReport Profile(s): DiagnosticReport Code Filter(s): Path: code ValueSet: Mammography
Parameters
Name | Use | Card. | Type | Documentation
Measurement Period | In | 0..1 | Period |
Patient | Out | 0..1 | Patient |
SDE Ethnicity | Out | 0..* | Coding |
SDE Payer | Out | 0..* | Resource |
SDE Race | Out | 0..* | Coding |
SDE Sex | Out | 0..1 | Coding |
Initial Population | Out | 0..1 | boolean |
Denominator | Out | 0..1 | boolean |
Unilateral Mastectomy Procedure | Out | 0..* | Procedure |
Right Mastectomy | Out | 0..* | Condition |
Left Mastectomy | Out | 0..* | Condition |
History Bilateral Mastectomy | Out | 0..* | Condition |
Bilateral Mastectomy Procedure | Out | 0..* | Procedure |
Numerator | Out | 0..1 | boolean |
Denominator Exclusion | Out | 0..1 | boolean |
Library Content
CQL Content |
    /*
    This example is a work in progress and should not be considered a final specification
    or recommendation for guidance. This example will help guide and direct the process
    of finding conventions and usage patterns that meet the needs of the various stakeholders
    in the measure development community.

    Based on CMS125v8 - Breast Cancer Screening
    */
    library EXM125 version '8.0.000'

    using FHIR version '4.0.1'

    include hl7.fhir.uv.cql.FHIRHelpers version '4.0.1' called FHIRHelpers

    include Hospice version '2.0.000' called Hospice
    include AdultOutpatientEncounters version '2.0.000' called AdultOutpatientEncounters
    include MATGlobalCommonFunctions version '5.0.000' called Global
    include SupplementalDataElements version '2.0.000' called SDE

    valueset "ONC Administrative Sex": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1'
    valueset "Race": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.836'
    valueset "Ethnicity": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.837'
    valueset "Payer": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.3591'
    valueset "Bilateral Mastectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1005'
    valueset "Female": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.560.100.2'
    valueset "Mammography": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1018'
    valueset "Unilateral Mastectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1020'
    valueset "History of bilateral mastectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1068'
    valueset "Status Post Left Mastectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1069'
    valueset "Status Post Right Mastectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1070'
    valueset "Left": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.122.12.1036'
    valueset "Right": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.122.12.1035'
    valueset "Unilateral Mastectomy, Unspecified Laterality": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1071'

    parameter "Measurement Period" Interval<DateTime>
      default Interval[@2019-01-01T00:00:00.0, @2020-01-01T00:00:00.0)

    context Patient

    define "SDE Ethnicity":
      SDE."SDE Ethnicity"

    define "SDE Payer":
      SDE."SDE Payer"

    define "SDE Race":
      SDE."SDE Race"

    define "SDE Sex":
      SDE."SDE Sex"

    define "Denominator":
    		"Initial Population"

    define "Unilateral Mastectomy Procedure":
    		[Procedure: "Unilateral Mastectomy"] UnilateralMastectomyProcedure
    				where Global."Normalize Interval"(UnilateralMastectomyProcedure.performed) ends before day of end of "Measurement Period"
    						and UnilateralMastectomyProcedure.status = 'completed'

    define "Right Mastectomy":
    		(
    				( [Condition: "Status Post Right Mastectomy"] C
              where C.clinicalStatus ~ ToConcept(Global."active")
            )
    				union (
    						[Condition: "Unilateral Mastectomy, Unspecified Laterality"] UnilateralMastectomyDiagnosis
    								where UnilateralMastectomyDiagnosis.bodySite in "Right"
                      and UnilateralMastectomyDiagnosis.clinicalStatus ~ ToConcept(Global."active")
    				)
    		) RightMastectomy
    				where Global."Normalize Interval"(RightMastectomy.onset) starts before day of end of "Measurement Period"

    define "Left Mastectomy":
    		(
    		    ( [Condition: "Status Post Left Mastectomy"] C
              where C.clinicalStatus ~ ToConcept(Global."active")
            )
    				union (
    						[Condition: "Unilateral Mastectomy, Unspecified Laterality"] UnilateralMastectomyDiagnosis
    								where UnilateralMastectomyDiagnosis.bodySite in "Left"
                      and UnilateralMastectomyDiagnosis.clinicalStatus ~ ToConcept(Global."active")
    				)
    		) LeftMastectomy
    				where Global."Normalize Interval"(LeftMastectomy.onset) starts before day of end of "Measurement Period"

    define "History Bilateral Mastectomy":
    		[Condition: "History of bilateral mastectomy"] BilateralMastectomyHistory
    				where Global."Normalize Interval"(BilateralMastectomyHistory.onset) starts before day of end of "Measurement Period"
              and BilateralMastectomyHistory.clinicalStatus ~ ToConcept(Global."active")

    define "Bilateral Mastectomy Procedure":
    		[Procedure: "Bilateral Mastectomy"] BilateralMastectomyPerformed
    				where Global."Normalize Interval"(BilateralMastectomyPerformed.performed) ends before day of end of "Measurement Period"
    						and BilateralMastectomyPerformed.status = 'completed'

    define "Numerator":
    		exists (
    				[DiagnosticReport: "Mammography"] Mammogram
    						where ( Global."Normalize Interval"(Mammogram.effective) ends 27 months or less before day of end of "Measurement Period" )
    								and Mammogram.status in { 'final', 'amended', 'corrected', 'appended' }
    		)

    define "Denominator Exclusion":
    		Hospice."Has Hospice"
    				or ( Count("Unilateral Mastectomy Procedure") = 2 )
    				or ( exists "Right Mastectomy" and exists "Left Mastectomy" )
    				or exists "History Bilateral Mastectomy"
    				or exists "Bilateral Mastectomy Procedure"

    define "Initial Population":
    		Patient.gender = 'female'
    				and Global."CalendarAgeInYearsAt"(FHIRHelpers.ToDate(Patient.birthDate), start of "Measurement Period") in Interval[51, 74]
    				and exists AdultOutpatientEncounters."Qualifying Encounters"
ELM XML Content |
    Encoded data
ELM JSON Content |
    Encoded data
Generated using version 0.5.4 of the sample-content-ig Liquid templates