Quality Measure Implementation Guide
2.0.0-ballot - STU 2 Ballot

Quality Measure Implementation Guide - Downloaded Version null See the Directory of published versions

## Library: EXM124 - Cervical Cancer Screening Library (Experimental)

Official URL: http://hl7.org/fhir/uv/cqm/Library/EXM124 | Version: 9.0.000 | Highlight text changes?
Standards status: Informative Active as of 2019-09-03 | Computable Name: EXM124
Other Identifiers: http://example.org/fhir/cqi/ecqm/Library/Identifier#EXM124 (use: official, ), OID:2.16.840.1.113883.4.642.40.61.28.9

This library is used as an example in the FHIR Quality Measure Implementation Guide

Metadata
Title | EXM124 - Cervical Cancer Screening Library
Version | 9.0.000
Identifier | EXM124
Identifier | urn:oid:2.16.840.1.113883.4.642.40.61.28.9
Approval Date | 2019-08-03
Last Review Date | 2019-08-03
Experimental | true
Jurisdiction | 001 from http://unstats.un.org/unsd/methods/m49/m49.htm
Topic | FHIR
Topic | CQL
Steward (Publisher) | HL7 International / Clinical Quality Information
Description | This library is used as an example in the FHIR Quality Measure Implementation Guide
Type | logic-library from http://terminology.hl7.org/CodeSystem/library-type
Dependency | Description: Library FHIRHelpers Resource: http://hl7.org/fhir/uv/cql/Library/FHIRHelpers|4.0.1 Canonical URL: `http://hl7.org/fhir/uv/cql/Library/FHIRHelpers|4.0.1`
Dependency | Description: Library Hospice Resource: Hospice FHIR Libraryversion: null2.0.000) Canonical URL: `http://hl7.org/fhir/uv/cqm/Library/Hospice|2.0.000`
Dependency | Description: Library AdultOutpatientEncounters Resource: Adult Outpatient Encounters Common Libraryversion: null2.0.000) Canonical URL: `http://hl7.org/fhir/uv/cqm/Library/AdultOutpatientEncounters|2.0.000`
Dependency | Description: Library Global Resource: MAT Global Common Functions FHIR Libraryversion: null5.0.000) Canonical URL: `http://hl7.org/fhir/uv/cqm/Library/MATGlobalCommonFunctions|5.0.000`
Dependency | Description: Library SDE Resource: Supplemental Data Elementsversion: null2.0.000) Canonical URL: `http://hl7.org/fhir/uv/cqm/Library/SupplementalDataElements|2.0.000`
Dependency | Description: Code System SNOMEDCT:2017-09 Resource: `http://snomed.info/sct|http://snomed.info/sct/731000124108/version/201709` Canonical URL: `http://snomed.info/sct|http://snomed.info/sct/731000124108/version/201709`
Dependency | Description: Value Set Hysterectomy with No Residual Cervix Resource: Hysterectomy with No Residual Cervix Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1014`
Dependency | Description: Value Set Pap Test Resource: Pap Test Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1017`
Dependency | Description: Value Set HPV Test Resource: HPV Test Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.110.12.1059`
Data Requirement | Type: Procedure Profile(s): Procedure Code Filter(s): Path: code ValueSet: Hysterectomy with No Residual Cervix
Data Requirement | Type: Condition Profile(s): Condition Code Filter(s): Path: code Code(s): SNOMED CT: 37687000 (Congenital absence of cervix (disorder)) (version = http://snomed.info/sct/731000124108/version/201709 )
Data Requirement | Type: Observation Profile(s): Observation Code Filter(s): Path: code ValueSet: Pap Test
Data Requirement | Type: Observation Profile(s): Observation Code Filter(s): Path: code ValueSet: HPV Test
Parameters
Name | Use | Card. | Type | Documentation
Measurement Period | In | 0..1 | Period |
Patient | Out | 0..1 | Patient |
SDE Ethnicity | Out | 0..* | Coding |
SDE Payer | Out | 0..* | Resource |
SDE Race | Out | 0..* | Coding |
SDE Sex | Out | 0..1 | Coding |
Initial Population | Out | 0..1 | boolean |
Denominator | Out | 0..1 | boolean |
Absence of Cervix | Out | 0..* | Resource |
Denominator Exclusion | Out | 0..1 | boolean |
Cervical Cytology Within 3 Years | Out | 0..* | Observation |
HPV Test Within 5 Years for Women Age 30 and Older | Out | 0..* | Observation |
Numerator | Out | 0..1 | boolean |
Library Content
CQL Content |
    /*
    This example is a work in progress and should not be considered a final specification
    or recommendation for guidance. This example will help guide and direct the process
    of finding conventions and usage patterns that meet the needs of the various stakeholders
    in the measure development community.

    Based on CMS124v9 - Cervical Cancer Screening
    */
    library EXM124 version '9.0.000'

    using FHIR version '4.0.1'

    include hl7.fhir.uv.cql.FHIRHelpers version '4.0.1' called FHIRHelpers

    include Hospice version '2.0.000' called Hospice
    include AdultOutpatientEncounters version '2.0.000' called AdultOutpatientEncounters
    include MATGlobalCommonFunctions version '5.0.000' called Global
    include SupplementalDataElements version '2.0.000' called SDE

    codesystem "SNOMEDCT:2017-09": 'http://snomed.info/sct' version 'http://snomed.info/sct/731000124108/version/201709'

    valueset "Hysterectomy with No Residual Cervix": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1014'
    valueset "Pap Test": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1017'
    valueset "HPV Test": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.110.12.1059'

    code "Congenital absence of cervix (disorder)": '37687000' from "SNOMEDCT:2017-09" display 'Congenital absence of cervix (disorder)'

    parameter "Measurement Period" Interval<DateTime>
      default Interval[@2019-01-01T00:00:00.0, @2020-01-01T00:00:00.0)

    context Patient

    define "SDE Ethnicity":
      SDE."SDE Ethnicity"

    define "SDE Payer":
      SDE."SDE Payer"

    define "SDE Race":
      SDE."SDE Race"

    define "SDE Sex":
      SDE."SDE Sex"

    define "Initial Population":
    	Patient.gender = 'female'
    		and Global."CalendarAgeInYearsAt"(FHIRHelpers.ToDate(Patient.birthDate), start of "Measurement Period") in Interval[23, 64]
    		and exists AdultOutpatientEncounters."Qualifying Encounters"

    define "Denominator":
    	"Initial Population"

    define "Denominator Exclusion":
    	Hospice."Has Hospice"
    		or exists "Absence of Cervix"

    define "Absence of Cervix":
      ([Procedure: "Hysterectomy with No Residual Cervix"] NoCervixProcedure
       where Global."Normalize Interval"(NoCervixProcedure.performed) ends on or before end of "Measurement Period"
         and NoCervixProcedure.status = 'completed'
         )
      union [Condition : "Congenital absence of cervix (disorder)"] NoCervixBirth
    		where Global."Normalize Interval"(NoCervixBirth.onset) starts on or before end of "Measurement Period"

    define "Numerator":
    	exists "Cervical Cytology Within 3 Years"
    		or exists "HPV Test Within 5 Years for Women Age 30 and Older"

    define "Cervical Cytology Within 3 Years":
    	[Observation: "Pap Test"] CervicalCytology
    		where CervicalCytology.value is not null
    			and CervicalCytology.status in { 'final', 'amended', 'corrected', 'preliminary' }
    		  and Global."Normalize Interval"(CervicalCytology.effective) ends 3 years or less on or before end of "Measurement Period"

    define "HPV Test Within 5 Years for Women Age 30 and Older":
    	[Observation: "HPV Test"] HPVTest
          where HPVTest.value is not null
            and HPVTest.status in { 'final', 'amended', 'corrected', 'preliminary' }
            and  Global."CalendarAgeInYearsAt"(FHIRHelpers.ToDate(Patient.birthDate), start of Global."Normalize Interval"(HPVTest.effective))>= 30
            and Global."Normalize Interval"(HPVTest.effective) ends 5 years or less on or before end of "Measurement Period"
ELM XML Content |
    Encoded data
ELM JSON Content |
    Encoded data
Generated using version 0.5.4 of the sample-content-ig Liquid templates