Quality Measure Implementation Guide
2.0.0-ballot - STU 2 Ballot

Quality Measure Implementation Guide - Downloaded Version null See the Directory of published versions

## Library: EXM55 - Median Emergency Department Visit Duration Library (Example Continuous Variable Measure Library) (Experimental)

Official URL: http://hl7.org/fhir/uv/cqm/Library/EXM55 | Version: 5.0.0 | Highlight text changes?
Standards status: Informative Active as of 2019-09-03 | Computable Name: EXM55
Other Identifiers: http://example.org/fhir/cqi/ecqm/Library/Identifier#EXM55 (use: official, ), OID:2.16.840.1.113883.4.642.40.61.28.13

This library is used as an example in the FHIR Quality Measure Implementation Guide

Metadata
Title | EXM55 - Median Emergency Department Visit Duration Library (Example Continuous Variable Measure Library)
Version | 5.0.0
Identifier | EXM55
Identifier | urn:oid:2.16.840.1.113883.4.642.40.61.28.13
Approval Date | 2019-08-03
Last Review Date | 2019-08-03
Experimental | true
Jurisdiction | 001 from http://unstats.un.org/unsd/methods/m49/m49.htm
Topic | FHIR
Topic | CQL
Steward (Publisher) | HL7 International / Clinical Quality Information
Description | This library is used as an example in the FHIR Quality Measure Implementation Guide
Type | logic-library from http://terminology.hl7.org/CodeSystem/library-type
Dependency | Description: Library FHIRHelpers Resource: http://hl7.org/fhir/uv/cql/Library/FHIRHelpers|4.0.1 Canonical URL: `http://hl7.org/fhir/uv/cql/Library/FHIRHelpers|4.0.1`
Dependency | Description: Code System Diagnosis Role Resource: Diagnosis Role Canonical URL: `http://terminology.hl7.org/CodeSystem/diagnosis-role`
Dependency | Description: Value Set Emergency Department Visit Resource: Emergency Department Visit Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.292`
Dependency | Description: Value Set Psychiatric/Mental Health Patient Resource: Psychiatric/Mental Health Diagnosis Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.299`
Dependency | Description: Value Set Hospital Settings Resource: Hospital Settings Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1111.126`
Data Requirement | Type: Encounter Profile(s): Encounter
Data Requirement | Type: Condition Profile(s): Condition Code Filter(s): Path: id
Data Requirement | Type: Encounter Profile(s): Encounter Code Filter(s): Path: type ValueSet: Emergency Department Visit
Parameters
Name | Use | Card. | Type | Documentation
Measurement Period | In | 0..1 | Period |
Patient | Out | 0..1 | Patient |
Inpatient Encounter | Out | 0..* | Encounter |
Initial Population | Out | 0..* | Encounter |
Measure Population | Out | 0..* | Encounter |
Measure Population Exclusion | Out | 0..* | Encounter |
Stratification 1 | Out | 0..* | Encounter |
Stratification 2 | Out | 0..* | Encounter |
Stratification 3 | Out | 0..* | Encounter |
Library Content
CQL Content |
    /*
    This example is a work in progress and should not be considered a final specification
    or recommendation for guidance. This example will help guide and direct the process
    of finding conventions and usage patterns that meet the needs of the various stakeholders
    in the measure development community.
    */

    library EXM55 version '5.0.0'

    using FHIR version '4.0.1'

    include hl7.fhir.uv.cql.FHIRHelpers version '4.0.1' called FHIRHelpers

    codesystem "Diagnosis Role": 'http://terminology.hl7.org/CodeSystem/diagnosis-role'

    valueset "Emergency Department Visit" : 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.292'
    valueset "Psychiatric/Mental Health Patient" : 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.299'
    valueset "Hospital Settings" : 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1111.126'

    code "Billing": 'billing' from "Diagnosis Role" display 'Billing'

    parameter "Measurement Period" Interval<DateTime>

    context Patient

    define "Initial Population" :
      "Inpatient Encounter" Encounter
        with ["Encounter" : "Emergency Department Visit"] ED
         such that ED.status = 'finished'
           and ED.period ends 1 hour or less before start of Encounter.period

    define "Measure Population" :
      "Initial Population"

    define "Inpatient Encounter" :
      ["Encounter"] Encounter
        where LengthInDays(Encounter.period) <= 120
          and Encounter.period ends during "Measurement Period"

    define "Measure Population Exclusion" :
      "Inpatient Encounter" Encounter
        with ["Encounter" : "Emergency Department Visit"] ED
          such that ED.period ends 1 hour or less before start of Encounter.period
            and ED.status = 'finished'
            and ED.hospitalization.admitSource in "Hospital Settings"

    define function "PrincipalDiagnosis"(Encounter Encounter):
    	(singleton from (Encounter.diagnosis D where D.use ~ ToConcept("Billing") and D.rank.value = 1)) PD
    		return singleton from ([Condition: id in "GetId"(PD.condition.reference)])

    define function "LengthInDays"(Value Interval<DateTime>):
    	difference in days between start of Value and end of Value

    define function "GetId"(uri String):
    	Last(Split(uri, '/'))

    define "Stratification 1" :
      "Inpatient Encounter" Encounter
        where not (PrincipalDiagnosis(Encounter).code in "Psychiatric/Mental Health Patient")

    define "Stratification 2" :
      "Inpatient Encounter" Encounter
        where PrincipalDiagnosis(Encounter).code in "Psychiatric/Mental Health Patient"

    define "Stratification 3" :
      "Inpatient Encounter" Encounter
        where PrincipalDiagnosis(Encounter) is null

    //Measure Observation
    define function "Related ED Visit" (Encounter "Encounter" ) :
      Last(["Encounter" : "Emergency Department Visit"] ED
        where ED.status = 'finished'
          and ED.period ends 1 hour or less before start of Encounter.period
        sort by start of period )

    define function "Measure Observation" (Encounter "Encounter" ) :
      duration in minutes of "Related ED Visit"(Encounter).period
ELM XML Content |
    Encoded data
ELM JSON Content |
    Encoded data
Generated using version 0.5.4 of the sample-content-ig Liquid templates