Quality Measure Implementation Guide
2.0.0-ballot - STU 2 Ballot

Quality Measure Implementation Guide - Downloaded Version null See the Directory of published versions

## Library: Supplemental Data Elements (Experimental)

Official URL: http://hl7.org/fhir/uv/cqm/Library/SupplementalDataElements | Version: 2.0.000 | Highlight text changes?
Standards status: Informative Active as of 2026-04-07 | Computable Name: SupplementalDataElements
Other Identifiers: OID:2.16.840.1.113883.4.642.40.61.28.32

This example illustrates logic for sharing supplemental data element calculation between multiple measures.

Metadata
Title | Supplemental Data Elements
Version | 2.0.000
Identifier | urn:oid:2.16.840.1.113883.4.642.40.61.28.32
Experimental | true
Jurisdiction | 001 from http://unstats.un.org/unsd/methods/m49/m49.htm
Topic | FHIR
Topic | CQL
Steward (Publisher) | HL7 International / Clinical Quality Information
Description | This example illustrates logic for sharing supplemental data element calculation between multiple measures.
Type | logic-library from http://terminology.hl7.org/CodeSystem/library-type
Dependency | Description: Library FHIRHelpers Resource: http://hl7.org/fhir/uv/cql/Library/FHIRHelpers|4.0.1 Canonical URL: `http://hl7.org/fhir/uv/cql/Library/FHIRHelpers|4.0.1`
Dependency | Description: Value Set Ethnicity Resource: Ethnicity Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.837`
Dependency | Description: Value Set ONC Administrative Sex Resource: ONC Administrative Sex Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1`
Dependency | Description: Value Set Payer Resource: Payer Type Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.3591`
Dependency | Description: Value Set Race Resource: Race Canonical URL: `http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.836`
Data Requirement | Type: Coverage Profile(s): Coverage Code Filter(s): Path: type ValueSet: Payer Type
Parameters
Name | Use | Card. | Type | Documentation
Patient | Out | 0..1 | Patient |
SDE Ethnicity | Out | 0..* | Coding |
SDE Payer | Out | 0..* | Resource |
SDE Race | Out | 0..* | Coding |
SDE Sex | Out | 0..1 | Coding |
Library Content
CQL Content |
    /*
    This example is a work in progress and should not be considered a final specification
    or recommendation for guidance. This example will help guide and direct the process
    of finding conventions and usage patterns that meet the needs of the various stakeholders
    in the measure development community.
    */
    library SupplementalDataElements version '2.0.000'

    using FHIR version '4.0.1'

    include hl7.fhir.uv.cql.FHIRHelpers version '4.0.1' called FHIRHelpers

    valueset "Ethnicity": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.837'
    valueset "ONC Administrative Sex": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1'
    valueset "Payer": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.3591'
    valueset "Race": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.836'

    context Patient

    define "SDE Ethnicity":
      (flatten (
          Patient.extension Extension
            where Extension.url = 'http://hl7.org/fhir/us/core/StructureDefinition/us-core-ethnicity'
              return Extension.extension
        )) E
          where E.url = 'ombCategory'
            or E.url = 'detailed'
          return E.value as Coding

    define "SDE Payer":
      [Coverage: type in "Payer"] Payer
            return {
              code: Payer.type,
              period: Payer.period
            }

    define "SDE Race":
      (flatten (
          Patient.extension Extension
            where Extension.url = 'http://hl7.org/fhir/us/core/StructureDefinition/us-core-race'
              return Extension.extension
        )) E
          where E.url = 'ombCategory'
            or E.url = 'detailed'
          return E.value as Coding

    define "SDE Sex":
      case
          when Patient.gender = 'male' then Code { code: 'M', system: 'http://hl7.org/fhir/v3/AdministrativeGender', display: 'Male' }
          when Patient.gender = 'female' then Code { code: 'F', system: 'http://hl7.org/fhir/v3/AdministrativeGender', display: 'Female' }
          else null
        end
ELM XML Content |
    Encoded data
ELM JSON Content |
    Encoded data
Generated using version 0.5.4 of the sample-content-ig Liquid templates