Quality Measure Implementation Guide
1.0.0 - STU 1

Quality Measure Implementation Guide - Downloaded Version null See the Directory of published versions

## Library: Example Executable Library (Experimental)

Official URL: http://hl7.org/fhir/uv/cqm/Library/EXMExecutableLibrary | Version: 2.0.0
Standards status: Informative | Computable Name: EXMExecutableLibrary
Other Identifiers: http://example.org/fhir/cqi/ecqm/Library/Identifier#EXMExecutableLibrary (use: official, ), OID:2.16.840.1.113883.4.642.40.61.28.16

This library is used as an example in the FHIR Quality Measure Implementation Guide

Metadata
Title | Example Executable Library
Version | 2.0.0
Identifier | EXMExecutableLibrary
Identifier | urn:oid:2.16.840.1.113883.4.642.40.61.28.16
Approval Date | 2019-08-03
Last Review Date | 2019-08-03
Experimental | true
Jurisdiction | Global (Whole world)
Steward (Publisher) | HL7 International / Clinical Quality Information
Description | This library is used as an example in the FHIR Quality Measure Implementation Guide
Type | Logic Library
Parameter | Name: Measurement Period Use: In Min Cardinality: 0 Max Cardinality: 1 Type: Period
Parameter | Name: Patient Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: Patient
Parameter | Name: Inpatient Encounter Use: Out Min Cardinality: 0 Max Cardinality: * Type: Encounter
Parameter | Name: Initial Population Use: Out Min Cardinality: 0 Max Cardinality: * Type: Encounter
Parameter | Name: Measure Population Use: Out Min Cardinality: 0 Max Cardinality: * Type: Encounter
Parameter | Name: Stratifier 1 Use: Out Min Cardinality: 0 Max Cardinality: * Type: Encounter
Parameter | Name: Stratifier 2 Use: Out Min Cardinality: 0 Max Cardinality: * Type: Encounter
Parameter | Name: Stratifier 3 Use: Out Min Cardinality: 0 Max Cardinality: * Type: Encounter
Parameter | Name: Stratifier 4 Use: Out Min Cardinality: 0 Max Cardinality: * Type: Encounter
Parameter | Name: SDE Ethnicity Use: Out Min Cardinality: 0 Max Cardinality: * Type: Coding
Parameter | Name: SDE Payer Use: Out Min Cardinality: 0 Max Cardinality: * Type: Resource
Parameter | Name: SDE Race Use: Out Min Cardinality: 0 Max Cardinality: * Type: Coding
Parameter | Name: SDE Sex Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: Coding
Data Requirement | Type: Patient Profile(s): Patient Must Support Elements: url, extension, value
Data Requirement | Type: Encounter Profile(s): Encounter Must Support Elements: type, status, period, use, rank, rank.value, condition, condition.reference Code Filter(s): Path: type ValueSet: Emergency Department Visit
Data Requirement | Type: Encounter Profile(s): Encounter Must Support Elements: period, use, rank, rank.value, condition, condition.reference
Data Requirement | Type: Condition Profile(s): Condition Must Support Elements: id Code Filter(s): Path: id
Data Requirement | Type: Coverage Profile(s): Coverage Must Support Elements: type, period Code Filter(s): Path: type ValueSet: Payer Type
Library Content
CQL Content |
    /*
    This example is purely for illustration purposes to show how all the elements of a
    FHIR-based quality measure are represented. It is intentionally simplified to show
    specific aspects of a measure, and is not intended as an example of a clinically
    meaningful measure.

    NOTE: This is the same library as EXMLogic, being used to illustrate the different flavors of profiles:
    * Computable: Focusing on computable/design-time aspects
    * Executable: Focusing on run-time aspects
    * Publishable: Focusing on knowledge management aspects
    */
    library EXMExecutableLibrary version '2.0.0'

    using FHIR version '4.0.1'

    include hl7.fhir.uv.cql.FHIRHelpers version '4.0.1' called FHIRHelpers

    codesystem "Diagnosis Role": 'http://terminology.hl7.org/CodeSystem/diagnosis-role'

    valueset "Emergency Department Visit" : 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.292'
    valueset "Psychiatric/Mental Health Patient" : 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.299'
    valueset "Hospital Settings" : 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1111.126'

    valueset "ONC Administrative Sex": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1'
    valueset "Race": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.836'
    valueset "Ethnicity": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.837'
    valueset "Payer": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.3591'

    code "Billing": 'billing' from "Diagnosis Role" display 'Billing'

    parameter "Measurement Period" Interval<DateTime>

    context Patient

    define "Initial Population" :
      "Inpatient Encounter" Encounter

    define "Measure Population" :
      "Initial Population"

    define function "Measure Observation" (Encounter "Encounter" ) :
      duration in minutes of "Related ED Visit"(Encounter).period

    define "Stratifier 1" :
      "Inpatient Encounter" Encounter
        where not (PrincipalDiagnosis(Encounter).code in "Psychiatric/Mental Health Patient")

    define "Stratifier 2" :
      "Inpatient Encounter" Encounter
        where PrincipalDiagnosis(Encounter).code in "Psychiatric/Mental Health Patient"

    define "Stratifier 3" :
      "Inpatient Encounter" Encounter
        where PrincipalDiagnosis(Encounter) is null

    define "Stratifier 4" :
      "Inpatient Encounter" Encounter
        where PrincipalDiagnosis(Encounter) is null

    define "Inpatient Encounter" :
      ["Encounter"] Encounter
        where LengthInDays(Encounter.period) <= 120
          and Encounter.period ends during "Measurement Period"

    define function "PrincipalDiagnosis"(Encounter Encounter):
    	(singleton from (Encounter.diagnosis D where D.use ~ ToConcept("Billing") and D.rank.value = 1)) PD
    		return singleton from ([Condition: id in "GetId"(PD.condition.reference)])

    define function "LengthInDays"(Value Interval<DateTime>):
    	difference in days between start of Value and end of Value

    define function "GetId"(uri String):
    	Last(Split(uri, '/'))

    //Measure Observation
    define function "Related ED Visit" (Encounter "Encounter" ) :
      Last(["Encounter" : "Emergency Department Visit"] ED
        where ED.status = 'finished'
          and ED.period ends 1 hour or less before start of Encounter.period
        sort by start of period )

    define "SDE Ethnicity":
      (flatten (
        Patient.extension Extension
          where Extension.url = 'http://hl7.org/fhir/us/core/StructureDefinition/us-core-ethnicity'
            return Extension.extension
      )) E
        where E.url = 'ombCategory'
          or E.url = 'detailed'
        return E.value as Coding

    define "SDE Payer":
        [Coverage: type in "Payer"] Payer
          return {
            code: Payer.type,
            period: Payer.period
          }

    define "SDE Race":
      (flatten (
        Patient.extension Extension
          where Extension.url = 'http://hl7.org/fhir/us/core/StructureDefinition/us-core-race'
            return Extension.extension
      )) E
        where E.url = 'ombCategory'
          or E.url = 'detailed'
        return E.value as Coding

    define "SDE Sex":
      case
        when Patient.gender = 'male' then Code { code: 'M', system: 'http://hl7.org/fhir/v3/AdministrativeGender', display: 'Male' }
        when Patient.gender = 'female' then Code { code: 'F', system: 'http://hl7.org/fhir/v3/AdministrativeGender', display: 'Female' }
        else null
      end
ELM XML Content |
    Encoded data (118716 characters)
ELM JSON Content |
    Encoded data (210892 characters)
Generated using version 0.4.9 of the sample-content-ig Liquid templates