Quality Measure Implementation Guide
1.0.0 - STU 1

Quality Measure Implementation Guide - Downloaded Version null See the Directory of published versions

## Library: CCS Component Library

Official URL: http://hl7.org/fhir/uv/cqm/Library/CCSComponent | Version: 0.0.001
Standards status: Trial-use | Maturity Level: 4 | Computable Name: CCSComponent
Other Identifiers: OID:2.16.840.1.113883.4.642.40.61.28.5

This library is the primary measure library for the Cervical Cancer Screening component of the composite measure examples in this implementation guide.

Metadata
Title | CCS Component Library
Version | 0.0.001
Identifier | urn:oid:2.16.840.1.113883.4.642.40.61.28.5
Status | Draft
Jurisdiction | Global (Whole world)
Steward (Publisher) | HL7 International / Clinical Quality Information
Description | This library is the primary measure library for the Cervical Cancer Screening component of the composite measure examples in this implementation guide.
Type | Logic Library
Parameter | Name: Measurement Period Use: In Min Cardinality: 0 Max Cardinality: 1 Type: Period
Parameter | Name: Patient Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: Patient
Parameter | Name: SDE Ethnicity Use: Out Min Cardinality: 0 Max Cardinality: * Type: Coding
Parameter | Name: SDE Payer Use: Out Min Cardinality: 0 Max Cardinality: * Type: Resource
Parameter | Name: SDE Race Use: Out Min Cardinality: 0 Max Cardinality: * Type: Coding
Parameter | Name: SDE Sex Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: Coding
Parameter | Name: Initial Population Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: boolean
Parameter | Name: Denominator Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: boolean
Parameter | Name: Flexible Sigmoidoscopy Performed Use: Out Min Cardinality: 0 Max Cardinality: * Type: Procedure
Parameter | Name: CT Colonography Performed Use: Out Min Cardinality: 0 Max Cardinality: * Type: Procedure
Parameter | Name: Total Colectomy Performed Use: Out Min Cardinality: 0 Max Cardinality: * Type: Procedure
Parameter | Name: Fecal Occult Blood Test Performed Use: Out Min Cardinality: 0 Max Cardinality: * Type: Observation
Parameter | Name: Fecal Immunochemical Test DNA Use: Out Min Cardinality: 0 Max Cardinality: * Type: Observation
Parameter | Name: Colonoscopy Performed Use: Out Min Cardinality: 0 Max Cardinality: * Type: Procedure
Parameter | Name: Numerator Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: boolean
Parameter | Name: Malignant Neoplasm Use: Out Min Cardinality: 0 Max Cardinality: * Type: Condition
Parameter | Name: Denominator Exclusion Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: boolean
Data Requirement | Type: Patient Profile(s): Patient
Data Requirement | Type: Procedure Profile(s): Procedure Must Support Elements: code, status, performed Code Filter(s): Path: code ValueSet: Flexible Sigmoidoscopy
Data Requirement | Type: Procedure Profile(s): Procedure Must Support Elements: code, status, performed Code Filter(s): Path: code ValueSet: CT Colonography
Data Requirement | Type: Procedure Profile(s): Procedure Must Support Elements: code, status, performed Code Filter(s): Path: code ValueSet: Total Colectomy
Data Requirement | Type: Procedure Profile(s): Procedure Must Support Elements: code, status, performed Code Filter(s): Path: code ValueSet: Colonoscopy
Data Requirement | Type: Observation Profile(s): Observation Must Support Elements: code, status, value, effective Code Filter(s): Path: code ValueSet: Fecal Occult Blood Test (FOBT)
Data Requirement | Type: Observation Profile(s): Observation Must Support Elements: code, status, value, effective Code Filter(s): Path: code ValueSet: sDNA FIT Test
Data Requirement | Type: Condition Profile(s): Condition Must Support Elements: code Code Filter(s): Path: code ValueSet: Malignant Neoplasm of Colon
Library Content
CQL Content |
    /*
    This example is a work in progress and should not be considered a final specification
    or recommendation for guidance. This example will help guide and direct the process
    of finding conventions and usage patterns that meet the needs of the various stakeholders
    in the measure development community.
    */
    library CCSComponent version '0.0.001'

    using FHIR version '4.0.1'

    include hl7.fhir.uv.cql.FHIRHelpers version '4.0.1' called FHIRHelpers

    include SupplementalDataElements version '2.0.000' called SDE
    include MATGlobalCommonFunctions version '5.0.000' called Global
    include AdultOutpatientEncounters version '2.0.000' called AdultOutpatientEncounters
    include Hospice version '2.0.000' called Hospice
    include AdvancedIllnessandFrailtyExclusion version '5.12.000' called Frailty

    codesystem "LOINC": 'http://loinc.org'

    valueset "Acute Inpatient": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1083'
    valueset "Advanced Illness": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.110.12.1082'
    valueset "Annual Wellness Visit": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1240'
    valueset "Care Services in Long-Term Residential Facility": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1014'
    valueset "Colonoscopy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1020'
    valueset "CT Colonography": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1038'
    valueset "Dementia Medications": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.196.12.1510'
    valueset "Discharged to Health Care Facility for Hospice Care": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.207'
    valueset "Discharged to Home for Hospice Care": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.209'
    valueset "ED": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1085'
    valueset "Encounter Inpatient": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.666.5.307'
    valueset "Fecal Occult Blood Test (FOBT)": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1011'
    valueset "FIT DNA": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1039'
    valueset "Flexible Sigmoidoscopy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1010'
    valueset "Frailty Device": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.118.12.1300'
    valueset "Frailty Diagnosis": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.113.12.1074'
    valueset "Frailty Encounter": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1088'
    valueset "Frailty Symptom": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.113.12.1075'
    valueset "Home Healthcare Services": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1016'
    valueset "Hospice care ambulatory": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1108.15'
    valueset "Malignant Neoplasm of Colon": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1001'
    valueset "Nonacute Inpatient": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1084'
    valueset "Nursing Facility Visit": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1012'
    valueset "Observation": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1086'
    valueset "Office Visit": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1001'
    valueset "Outpatient": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1087'
    valueset "Preventive Care Services - Established Office Visit, 18 and Up": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1025'
    valueset "Preventive Care Services-Initial Office Visit, 18 and Up": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1023'
    valueset "Total Colectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1019'

    code "Birth date": '21112-8' from "LOINC" display 'Birth date'

    parameter "Measurement Period" Interval<DateTime>

    context Patient

    define "SDE Ethnicity":
      SDE."SDE Ethnicity"

    define "SDE Payer":
      SDE."SDE Payer"

    define "SDE Race":
      SDE."SDE Race"

    define "SDE Sex":
      SDE."SDE Sex"

    define "Initial Population":
      Global."CalendarAgeInYearsAt" ( FHIRHelpers.ToDate ( Patient.birthDate ), start of "Measurement Period" ) in Interval[50, 75]
          and exists AdultOutpatientEncounters."Qualifying Encounters"

    define "Denominator":
      "Initial Population"

    define "Flexible Sigmoidoscopy Performed":
      [Procedure: "Flexible Sigmoidoscopy"] FlexibleSigmoidoscopy
          where FlexibleSigmoidoscopy.status = 'completed'
            and Global."Normalize Interval" ( FlexibleSigmoidoscopy.performed ) ends 5 years or less on or before
            end of "Measurement Period"

    define "CT Colonography Performed":
      [Procedure: "CT Colonography"] Colonography
          where Colonography.status = 'completed'
            and Global."Normalize Interval" ( Colonography.performed ) ends 5 years or less on or before
            end of "Measurement Period"

    define "Total Colectomy Performed":
      [Procedure: "Total Colectomy"] Colectomy
          where Colectomy.status = 'completed'
            and Global."Normalize Interval" ( Colectomy.performed ) starts on or before
            end of "Measurement Period"

    define "Fecal Occult Blood Test Performed":
      [Observation: "Fecal Occult Blood Test (FOBT)"] FecalOccultResult
          where FecalOccultResult.status in { 'final', 'amended', 'corrected', 'preliminary' }
            and FecalOccultResult.value is not null
            and Global."Normalize Interval" ( FecalOccultResult.effective ) during day of "Measurement Period"

    define "Fecal Immunochemical Test DNA":
      [Observation: "FIT DNA"] FitDNA
          where FitDNA.status in { 'final', 'amended', 'corrected', 'preliminary' }
            and FitDNA.value is not null
            and Global."Normalize Interval" ( FitDNA.effective ) occurs 3 years or less on or before day of
            end of "Measurement Period"

    define "Colonoscopy Performed":
      [Procedure: "Colonoscopy"] Colonoscopy
          where Colonoscopy.status = 'completed'
            and Global."Normalize Interval" ( Colonoscopy.performed ) ends 10 years or less on or before
            end of "Measurement Period"

    define "Numerator":
      exists "Colonoscopy Performed"
          or exists "Fecal Occult Blood Test Performed"
          or exists "Flexible Sigmoidoscopy Performed"
          or exists "Fecal Immunochemical Test DNA"
          or exists "CT Colonography Performed"

    define "Malignant Neoplasm":
      [Condition: "Malignant Neoplasm of Colon"] ColorectalCancer
          where Global."Prevalence Period" ( ColorectalCancer ) starts on or before
          end of "Measurement Period"

    define "Denominator Exclusion":
      Hospice."Has Hospice"
          or exists "Malignant Neoplasm"
          or exists "Total Colectomy Performed"
          or Frailty."Advanced Illness and Frailty Exclusion Not Including Over Age 80"
            and Frailty."Long Term Care Periods Longer Than 90 Consecutive Days"
ELM XML Content |
    Encoded data (112116 characters)
ELM JSON Content |
    Encoded data (202108 characters)
Generated using version 0.4.9 of the sample-content-ig Liquid templates