Quality Measure Implementation Guide
1.0.0 - STU 1

Quality Measure Implementation Guide - Downloaded Version null See the Directory of published versions

## Library: Hospice FHIR Library (Experimental)

Official URL: http://hl7.org/fhir/uv/cqm/Library/Hospice | Version: 2.0.000
Standards status: Informative | Computable Name: Hospice
Other Identifiers: http://example.org/fhir/cqi/ecqm/Library/Identifier#Hospice (use: official, ), OID:2.16.840.1.113883.4.642.40.61.28.24

This library is used as an example in the FHIR Quality Measure Implementation Guide

Metadata
Title | Hospice FHIR Library
Version | 2.0.000
Identifier | Hospice
Identifier | urn:oid:2.16.840.1.113883.4.642.40.61.28.24
Approval Date | 2019-08-03
Last Review Date | 2019-08-03
Experimental | true
Jurisdiction | Global (Whole world)
Steward (Publisher) | HL7 International / Clinical Quality Information
Description | This library is used as an example in the FHIR Quality Measure Implementation Guide
Type | Logic Library
Parameter | Name: Measurement Period Use: In Min Cardinality: 0 Max Cardinality: 1 Type: Period
Parameter | Name: Patient Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: Patient
Parameter | Name: Has Hospice Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: boolean
Data Requirement | Type: Patient Profile(s): Patient
Data Requirement | Type: Encounter Profile(s): Encounter Must Support Elements: type, status, hospitalization, hospitalization.dischargeDisposition, period Code Filter(s): Path: type ValueSet: Encounter Inpatient
Data Requirement | Type: ServiceRequest Profile(s): ServiceRequest Must Support Elements: code, intent, authoredOn Code Filter(s): Path: code ValueSet: Hospice Care Ambulatory
Data Requirement | Type: Procedure Profile(s): Procedure Must Support Elements: code, status, performed Code Filter(s): Path: code ValueSet: Hospice Care Ambulatory
Library Content
CQL Content |
    /*
    This example is a work in progress and should not be considered a final specification
    or recommendation for guidance. This example will help guide and direct the process
    of finding conventions and usage patterns that meet the needs of the various stakeholders
    in the measure development community.
    */
    library Hospice version '2.0.000'

    using FHIR version '4.0.1'

    include hl7.fhir.uv.cql.FHIRHelpers version '4.0.1' called FHIRHelpers

    include MATGlobalCommonFunctions version '5.0.000' called Global

    codesystem "SNOMEDCT:2017-09": 'http://snomed.info/sct' version 'http://snomed.info/sct/731000124108/version/201709'

    valueset "Encounter Inpatient": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.666.5.307'
    valueset "Hospice care ambulatory": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1108.15'

    code "Discharge to healthcare facility for hospice care (procedure)": '428371000124100' from "SNOMEDCT:2017-09" display 'Discharge to healthcare facility for hospice care (procedure)'
    code "Discharge to home for hospice care (procedure)": '428361000124107' from "SNOMEDCT:2017-09" display 'Discharge to home for hospice care (procedure)'

    parameter "Measurement Period" Interval<DateTime>
      default Interval[@2019-01-01T00:00:00.0, @2020-01-01T00:00:00.0)

    context Patient

    define "Has Hospice":
    	exists (
        [Encounter: "Encounter Inpatient"] DischargeHospice
    			where DischargeHospice.status = 'finished'
    		    and (
    	        DischargeHospice.hospitalization.dischargeDisposition ~ "Discharge to home for hospice care (procedure)"
    				    or DischargeHospice.hospitalization.dischargeDisposition ~ "Discharge to healthcare facility for hospice care (procedure)"
    	    	)
    				and DischargeHospice.period ends during "Measurement Period"
    	)
        or exists (
          [ServiceRequest: "Hospice care ambulatory"] HospiceOrder
            where HospiceOrder.intent = 'order'
                and HospiceOrder.authoredOn in "Measurement Period"
        )
        or exists (
          [Procedure: "Hospice care ambulatory"] HospicePerformed
            where HospicePerformed.status = 'completed'
              and Global."Normalize Interval"(HospicePerformed.performed) overlaps "Measurement Period"
        )
ELM XML Content |
    Encoded data (44140 characters)
ELM JSON Content |
    Encoded data (81052 characters)
Generated using version 0.4.9 of the sample-content-ig Liquid templates