Quality Measure Implementation Guide
1.0.0 - STU 1

Quality Measure Implementation Guide - Downloaded Version null See the Directory of published versions

## Library: EXM130 - Colorectal Cancer Screening Library (Experimental)

Official URL: http://hl7.org/fhir/uv/cqm/Library/EXM130 | Version: 8.0.000
Standards status: Informative | Computable Name: EXM130
Other Identifiers: http://example.org/fhir/cqi/ecqm/Library/Identifier#EXM130 (use: official, ), OID:2.16.840.1.113883.4.642.40.61.28.11

This library is used as an example in the FHIR Quality Measure Implementation Guide

Metadata
Title | EXM130 - Colorectal Cancer Screening Library
Version | 8.0.000
Identifier | EXM130
Identifier | urn:oid:2.16.840.1.113883.4.642.40.61.28.11
Approval Date | 2019-08-03
Last Review Date | 2019-08-03
Experimental | true
Jurisdiction | Global (Whole world)
Steward (Publisher) | HL7 International / Clinical Quality Information
Description | This library is used as an example in the FHIR Quality Measure Implementation Guide
Type | Logic Library
Parameter | Name: Measurement Period Use: In Min Cardinality: 0 Max Cardinality: 1 Type: Period
Parameter | Name: Patient Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: Patient
Parameter | Name: SDE Ethnicity Use: Out Min Cardinality: 0 Max Cardinality: * Type: Coding
Parameter | Name: SDE Payer Use: Out Min Cardinality: 0 Max Cardinality: * Type: Resource
Parameter | Name: SDE Race Use: Out Min Cardinality: 0 Max Cardinality: * Type: Coding
Parameter | Name: SDE Sex Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: Coding
Parameter | Name: Denominator Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: boolean
Parameter | Name: Flexible Sigmoidoscopy Performed Use: Out Min Cardinality: 0 Max Cardinality: * Type: Procedure
Parameter | Name: CT Colonography Performed Use: Out Min Cardinality: 0 Max Cardinality: * Type: Procedure
Parameter | Name: Total Colectomy Performed Use: Out Min Cardinality: 0 Max Cardinality: * Type: Procedure
Parameter | Name: Malignant Neoplasm Ever Use: Out Min Cardinality: 0 Max Cardinality: * Type: Condition
Parameter | Name: Fecal Occult Blood Test Performed Use: Out Min Cardinality: 0 Max Cardinality: * Type: Observation
Parameter | Name: Fecal Immunochemical Test DNA Use: Out Min Cardinality: 0 Max Cardinality: * Type: Observation
Parameter | Name: Colonoscopy Performed Use: Out Min Cardinality: 0 Max Cardinality: * Type: Procedure
Parameter | Name: Numerator Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: boolean
Parameter | Name: Denominator Exclusion Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: boolean
Parameter | Name: Initial Population Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: boolean
Data Requirement | Type: Patient Profile(s): Patient
Data Requirement | Type: Procedure Profile(s): Procedure Must Support Elements: code, status, performed Code Filter(s): Path: code ValueSet: Flexible Sigmoidoscopy
Data Requirement | Type: Procedure Profile(s): Procedure Must Support Elements: code, status, performed Code Filter(s): Path: code ValueSet: CT Colonography
Data Requirement | Type: Procedure Profile(s): Procedure Must Support Elements: code, status, performed Code Filter(s): Path: code ValueSet: Total Colectomy
Data Requirement | Type: Procedure Profile(s): Procedure Must Support Elements: code, status, performed Code Filter(s): Path: code ValueSet: Colonoscopy
Data Requirement | Type: Condition Profile(s): Condition Must Support Elements: code, onset Code Filter(s): Path: code ValueSet: Malignant Neoplasm of Colon
Data Requirement | Type: Observation Profile(s): Observation Must Support Elements: code, status, value, effective Code Filter(s): Path: code ValueSet: Fecal Occult Blood Test (FOBT)
Data Requirement | Type: Observation Profile(s): Observation Must Support Elements: code, status, value, effective Code Filter(s): Path: code ValueSet: sDNA FIT Test
Library Content
CQL Content |
    /*
    This example is a work in progress and should not be considered a final specification
    or recommendation for guidance. This example will help guide and direct the process
    of finding conventions and usage patterns that meet the needs of the various stakeholders
    in the measure development community.

    Based on CMS130v8 - Colorectal Cancer Screening
    */
    library EXM130 version '8.0.000'

    using FHIR version '4.0.1'

    include hl7.fhir.uv.cql.FHIRHelpers version '4.0.1' called FHIRHelpers

    include Hospice version '2.0.000' called Hospice
    include AdultOutpatientEncounters version '2.0.000' called AdultOutpatientEncounters
    include MATGlobalCommonFunctions version '5.0.000' called Global
    include SupplementalDataElements version '2.0.000' called SDE

    valueset "ONC Administrative Sex": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1'
    valueset "Race": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.836'
    valueset "Ethnicity": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.837'
    valueset "Payer": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.3591'
    valueset "Colonoscopy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1020'
    valueset "Fecal Occult Blood Test (FOBT)": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1011'
    valueset "Flexible Sigmoidoscopy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1010'
    valueset "Malignant Neoplasm of Colon": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1001'
    valueset "Total Colectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1019'
    valueset "FIT DNA": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1039'
    valueset "CT Colonography": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1038'

    parameter "Measurement Period" Interval<DateTime>
      default Interval[@2019-01-01T00:00:00.0, @2020-01-01T00:00:00.0)

    context Patient

    define "SDE Ethnicity":
      SDE."SDE Ethnicity"

    define "SDE Payer":
      SDE."SDE Payer"

    define "SDE Race":
      SDE."SDE Race"

    define "SDE Sex":
      SDE."SDE Sex"

    define "Denominator":
    	true

    define "Flexible Sigmoidoscopy Performed":
    	[Procedure: "Flexible Sigmoidoscopy"] FlexibleSigmoidoscopy
    		where FlexibleSigmoidoscopy.status = 'completed'
    			and Global."Normalize Interval"(FlexibleSigmoidoscopy.performed) ends 5 years or less on or before end of "Measurement Period"

    define "CT Colonography Performed":
    	[Procedure: "CT Colonography"] Colonography
    		where Colonography.status = 'completed'
    			and Global."Normalize Interval"(Colonography.performed) ends 5 years or less on or before end of "Measurement Period"

    define "Total Colectomy Performed":
    	[Procedure: "Total Colectomy"] Colectomy
    		where Colectomy.status = 'completed'
    			and Global."Normalize Interval"(Colectomy.performed) starts on or before end of "Measurement Period"

    define "Malignant Neoplasm Ever":
    	[Condition: "Malignant Neoplasm of Colon"] ColorectalCancer
    		where Global."Normalize Interval"(ColorectalCancer.onset) starts on or before end of "Measurement Period"

    define "Fecal Occult Blood Test Performed":
    	[Observation: "Fecal Occult Blood Test (FOBT)"] FecalOccultResult
    		where FecalOccultResult.status in {'final', 'amended', 'corrected', 'preliminary'}
    			and FecalOccultResult.value is not null
    			and Global."Normalize Interval"(FecalOccultResult.effective) during day of "Measurement Period"

    define "Fecal Immunochemical Test DNA":
    	[Observation: "FIT DNA"] FitDNA
    		where FitDNA.status in {'final', 'amended', 'corrected', 'preliminary'}
    			and FitDNA.value is not null
    			and Global."Normalize Interval"(FitDNA.effective) occurs 3 years or less on or before day of end of "Measurement Period"

    define "Colonoscopy Performed":
    	[Procedure: "Colonoscopy"] Colonoscopy
    		where Colonoscopy.status = 'completed'
    		  and Global."Normalize Interval"(Colonoscopy.performed) ends 10 years or less on or before end of "Measurement Period"

    define "Numerator":
    	exists "Colonoscopy Performed"
    		or exists "Fecal Occult Blood Test Performed"
    		or exists "Flexible Sigmoidoscopy Performed"
    		or exists "Fecal Immunochemical Test DNA"
    		or exists "CT Colonography Performed"

    define "Denominator Exclusion":
    	Hospice."Has Hospice"
    		or exists "Malignant Neoplasm Ever"
    		or exists "Total Colectomy Performed"

    define "Initial Population":
    	Global."CalendarAgeInYearsAt"(FHIRHelpers.ToDate(Patient.birthDate), start of "Measurement Period") in Interval[50, 75]
    			and exists AdultOutpatientEncounters."Qualifying Encounters"
ELM XML Content |
    Encoded data (98820 characters)
ELM JSON Content |
    Encoded data (184488 characters)
Generated using version 0.4.9 of the sample-content-ig Liquid templates