Quality Measure Implementation Guide
1.0.0 - STU 1

Quality Measure Implementation Guide - Downloaded Version null See the Directory of published versions

## Library: EXM146 - Example Proportion Measure Library (Experimental)

Official URL: http://hl7.org/fhir/uv/cqm/Library/EXM146 | Version: 4.0.0
Standards status: Informative | Computable Name: EXM146
Other Identifiers: http://example.org/fhir/cqi/ecqm/Library/Identifier#EXM146 (use: official, ), OID:2.16.840.1.113883.4.642.40.61.28.12

This library is used as an example in the FHIR Quality Measure Implementation Guide

Metadata
Title | EXM146 - Example Proportion Measure Library
Version | 4.0.0
Identifier | EXM146
Identifier | urn:oid:2.16.840.1.113883.4.642.40.61.28.12
Approval Date | 2019-08-03
Last Review Date | 2019-08-03
Experimental | true
Jurisdiction | Global (Whole world)
Steward (Publisher) | HL7 International / Clinical Quality Information
Description | This library is used as an example in the FHIR Quality Measure Implementation Guide
Type | Logic Library
Parameter | Name: Measurement Period Use: In Min Cardinality: 0 Max Cardinality: 1 Type: Period
Parameter | Name: Patient Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: Patient
Parameter | Name: Is Between 2 and 17 Years of Age at Start of Measurement Period Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: boolean
Parameter | Name: Antibiotics Use: Out Min Cardinality: 0 Max Cardinality: * Type: MedicationRequest
Parameter | Name: Pharyngitis Use: Out Min Cardinality: 0 Max Cardinality: * Type: Condition
Parameter | Name: Measurement Period Encounters Use: Out Min Cardinality: 0 Max Cardinality: * Type: Encounter
Parameter | Name: Pharyngitis Encounters With Antibiotics Use: Out Min Cardinality: 0 Max Cardinality: * Type: Encounter
Parameter | Name: Initial Population Use: Out Min Cardinality: 0 Max Cardinality: * Type: Encounter
Parameter | Name: Denominator Use: Out Min Cardinality: 0 Max Cardinality: * Type: Encounter
Parameter | Name: Pharyngitis With Prior Antibiotics Use: Out Min Cardinality: 0 Max Cardinality: * Type: Condition
Parameter | Name: Excluded Encounters Use: Out Min Cardinality: 0 Max Cardinality: * Type: Encounter
Parameter | Name: Denominator Exclusions Use: Out Min Cardinality: 0 Max Cardinality: * Type: Encounter
Parameter | Name: Strep Test Encounters Use: Out Min Cardinality: 0 Max Cardinality: * Type: Encounter
Parameter | Name: Numerator Use: Out Min Cardinality: 0 Max Cardinality: * Type: Encounter
Data Requirement | Type: Patient Profile(s): Patient
Data Requirement | Type: MedicationRequest Profile(s): MedicationRequest Must Support Elements: medication, status, intent, authoredOn Code Filter(s): Path: medication ValueSet: Antibiotic Medications for Pharyngitis
Data Requirement | Type: Condition Profile(s): Condition Must Support Elements: code, clinicalStatus, verificationStatus, onset Code Filter(s): Path: code ValueSet: Acute Pharyngitis
Data Requirement | Type: Condition Profile(s): Condition Must Support Elements: code, clinicalStatus, verificationStatus, onset Code Filter(s): Path: code ValueSet: Acute Tonsillitis
Data Requirement | Type: Encounter Profile(s): Encounter Must Support Elements: type, period, status Code Filter(s): Path: type ValueSet: Ambulatory/ED Visit
Data Requirement | Type: Observation Profile(s): Observation Must Support Elements: code, value, effective Code Filter(s): Path: code ValueSet: Group A Streptococcus Test
Library Content
CQL Content |
    /*
    This example is a work in progress and should not be considered a final specification
    or recommendation for guidance. This example will help guide and direct the process
    of finding conventions and usage patterns that meet the needs of the various stakeholders
    in the measure development community.
    */
    library EXM146 version '4.0.0'

    using FHIR version '4.0.1'

    include hl7.fhir.uv.cql.FHIRHelpers version '4.0.1' called FHIRHelpers

    include Common version '2.0.0' called Common
    include MATGlobalCommonFunctions version '5.0.000' called Global

    valueset "Acute Pharyngitis": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.102.12.1011'
    valueset "Acute Tonsillitis": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.102.12.1012'
    valueset "Ambulatory/ED Visit": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1061'
    valueset "Antibiotic Medications": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.196.12.1001'
    valueset "Group A Streptococcus Test": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1012'

    parameter "Measurement Period" Interval<DateTime>

    context Patient

    define "Is Between 2 and 17 Years of Age at Start of Measurement Period":
       AgeInYearsAt(start of "Measurement Period") >= 2
          and AgeInYearsAt(start of "Measurement Period") <= 17

    define "Antibiotics":
       [MedicationRequest: medication in "Antibiotic Medications"] Prescription
         where Prescription.status = 'active'
           and Prescription.intent = 'order'

    define "Pharyngitis":
       ([Condition: code in "Acute Pharyngitis"]
         union [Condition: code in "Acute Tonsillitis"]) Pharyngitis
         where Pharyngitis.clinicalStatus ~ Global.active
           and Pharyngitis.verificationStatus ~ Global.confirmed

    define "Measurement Period Encounters":
       [Encounter: "Ambulatory/ED Visit"] Encounter
          where Encounter.period during "Measurement Period"
            and Encounter.status = 'finished'
            and "Is Between 2 and 17 Years of Age at Start of Measurement Period"

    define "Pharyngitis Encounters With Antibiotics":
       "Measurement Period Encounters" Encounters
          with "Pharyngitis" Pharyngitis such that
             Common."Includes Or Starts During"(Pharyngitis, Encounters)
          with "Antibiotics" Antibiotics such that Antibiotics.authoredOn
             3 days or less after FHIRHelpers.ToInterval(Encounters.period)

    define "Initial Population":
       "Pharyngitis Encounters With Antibiotics"

    define "Denominator":
       "Initial Population"

    define "Pharyngitis With Prior Antibiotics":
       "Pharyngitis" Pharyngitis
          with "Antibiotics" Antibiotics such that
             Antibiotics.authoredOn 30 days or less before Pharyngitis.onset

    define "Excluded Encounters":
       "Pharyngitis Encounters With Antibiotics" Encounters
          with "Pharyngitis With Prior Antibiotics" Pharyngitis such that
             Common."Includes Or Starts During"(Pharyngitis, Encounters)

    define "Denominator Exclusions":
      "Excluded Encounters"

    define "Strep Test Encounters":
       "Pharyngitis Encounters With Antibiotics" Encounters
          with [Observation: code in "Group A Streptococcus Test"] Tests
             such that Tests.value is not null
                and Tests.effective starts during
                   Interval[start of FHIRHelpers.ToInterval(Encounters.period) - 3 days,
                     end of FHIRHelpers.ToInterval(Encounters.period) + 3 days]

    define "Numerator":
       "Strep Test Encounters"
ELM XML Content |
    Encoded data (88576 characters)
ELM JSON Content |
    Encoded data (165744 characters)
Generated using version 0.4.9 of the sample-content-ig Liquid templates