Quality Measure Implementation Guide
1.0.0 - STU 1

Quality Measure Implementation Guide - Downloaded Version null See the Directory of published versions

## Library: PVS Component Library (Experimental)

Official URL: http://hl7.org/fhir/uv/cqm/Library/PVSComponent | Version: 0.0.001
Standards status: Informative | Computable Name: PVSComponent
Other Identifiers: OID:2.16.840.1.113883.4.642.40.61.28.30

Pneumococcal Vaccination Status for Older Adults

Metadata
Title | PVS Component Library
Version | 0.0.001
Identifier | urn:oid:2.16.840.1.113883.4.642.40.61.28.30
Experimental | true
Jurisdiction | Global (Whole world)
Steward (Publisher) | HL7 International / Clinical Quality Information
Description | Pneumococcal Vaccination Status for Older Adults
Type | Logic Library
Parameter | Name: Measurement Period Use: In Min Cardinality: 0 Max Cardinality: 1 Type: Period
Parameter | Name: Patient Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: Patient
Parameter | Name: SDE Ethnicity Use: Out Min Cardinality: 0 Max Cardinality: * Type: Coding
Parameter | Name: SDE Payer Use: Out Min Cardinality: 0 Max Cardinality: * Type: Resource
Parameter | Name: SDE Race Use: Out Min Cardinality: 0 Max Cardinality: * Type: Coding
Parameter | Name: SDE Sex Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: Coding
Parameter | Name: Qualifying Encounters Use: Out Min Cardinality: 0 Max Cardinality: * Type: Encounter
Parameter | Name: Initial Population Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: boolean
Parameter | Name: Denominator Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: boolean
Parameter | Name: Denominator Exclusions Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: boolean
Parameter | Name: Numerator Use: Out Min Cardinality: 0 Max Cardinality: 1 Type: boolean
Data Requirement | Type: Patient Profile(s): Patient
Data Requirement | Type: Encounter Profile(s): Encounter Must Support Elements: type, period, status Code Filter(s): Path: type ValueSet: Office Visit
Data Requirement | Type: Encounter Profile(s): Encounter Must Support Elements: type, period, status Code Filter(s): Path: type ValueSet: Annual Wellness Visit
Data Requirement | Type: Encounter Profile(s): Encounter Must Support Elements: type, period, status Code Filter(s): Path: type ValueSet: Preventive Care Services Established Office Visit, 18 and Up
Data Requirement | Type: Encounter Profile(s): Encounter Must Support Elements: type, period, status Code Filter(s): Path: type ValueSet: Preventive Care Services Initial Office Visit, 18 and Up
Data Requirement | Type: Encounter Profile(s): Encounter Must Support Elements: type, period, status Code Filter(s): Path: type ValueSet: Home Healthcare Services
Data Requirement | Type: Encounter Profile(s): Encounter Must Support Elements: type, period, status Code Filter(s): Path: type ValueSet: Discharge Services Nursing Facility
Data Requirement | Type: Encounter Profile(s): Encounter Must Support Elements: type, period, status Code Filter(s): Path: type ValueSet: Nursing Facility Visit
Data Requirement | Type: Encounter Profile(s): Encounter Must Support Elements: type, period, status Code Filter(s): Path: type ValueSet: Care Services in Long Term Residential Facility
Data Requirement | Type: Immunization Profile(s): Immunization Must Support Elements: vaccineCode, status, occurrence Code Filter(s): Path: vaccineCode ValueSet: Pneumococcal Vaccine
Data Requirement | Type: Procedure Profile(s): Procedure Must Support Elements: code, status, performed Code Filter(s): Path: code ValueSet: Pneumococcal Vaccine Administered
Library Content
CQL Content |
    /*
    This example is a work in progress and should not be considered a final specification
    or recommendation for guidance. This example will help guide and direct the process
    of finding conventions and usage patterns that meet the needs of the various stakeholders
    in the measure development community.
    */
    library PVSComponent version '0.0.001'

    using FHIR version '4.0.1'

    include hl7.fhir.uv.cql.FHIRHelpers version '4.0.1' called FHIRHelpers

    include SupplementalDataElements version '2.0.000' called SDE
    include MATGlobalCommonFunctions version '5.0.000' called Global
    include Hospice version '2.0.000' called Hospice

    codesystem "LOINC": 'http://loinc.org'

    valueset "Annual Wellness Visit": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.526.3.1240'
    valueset "Care Services in Long-Term Residential Facility": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1014'
    valueset "Discharge Services - Nursing Facility": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.11.1065'
    valueset "Discharged to Health Care Facility for Hospice Care": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.207'
    valueset "Discharged to Home for Hospice Care": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.117.1.7.1.209'
    valueset "Encounter Inpatient": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.666.5.307'
    valueset "Home Healthcare Services": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1016'
    valueset "Hospice care ambulatory": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1108.15'
    valueset "Nursing Facility Visit": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1012'
    valueset "Office Visit": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1001'
    valueset "Pneumococcal Vaccine": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.110.12.1027'
    valueset "Pneumococcal Vaccine Administered": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.110.12.1034'
    valueset "Preventive Care Services - Established Office Visit, 18 and Up": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1025'
    valueset "Preventive Care Services-Initial Office Visit, 18 and Up": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.101.12.1023'

    code "Birth date": '21112-8' from "LOINC" display 'Birth date'

    parameter "Measurement Period" Interval<DateTime>

    context Patient

    define "SDE Ethnicity":
      SDE."SDE Ethnicity"

    define "SDE Payer":
      SDE."SDE Payer"

    define "SDE Race":
      SDE."SDE Race"

    define "SDE Sex":
      SDE."SDE Sex"

    define "Initial Population":
      Global."CalendarAgeInYearsAt" ( FHIRHelpers.ToDate ( Patient.birthDate ), start of "Measurement Period" ) >= 65
          and exists "Qualifying Encounters"

    define "Qualifying Encounters":
      ( [Encounter: "Office Visit"]
          union [Encounter: "Annual Wellness Visit"]
          union [Encounter: "Preventive Care Services - Established Office Visit, 18 and Up"]
          union [Encounter: "Preventive Care Services-Initial Office Visit, 18 and Up"]
          union [Encounter: "Home Healthcare Services"]
          union [Encounter: "Discharge Services - Nursing Facility"]
          union [Encounter: "Nursing Facility Visit"]
          union [Encounter: "Care Services in Long-Term Residential Facility"] ) ValidEncounter
          where ValidEncounter.period during "Measurement Period"
            and ValidEncounter.status = 'finished'

    define "Denominator":
      "Initial Population"

    define "Denominator Exclusions":
      Hospice."Has Hospice"

    define "Numerator":
      exists ( [Immunization: "Pneumococcal Vaccine"] PneumococcalVaccine
            where PneumococcalVaccine.status = 'completed'
              and PneumococcalVaccine.occurrence as dateTime on or before
              end of "Measurement Period"
        )
          or exists ( [Procedure: "Pneumococcal Vaccine Administered"] PneumococcalVaccineGiven
              where PneumococcalVaccineGiven.status = 'completed'
                and PneumococcalVaccineGiven.performed as Period on or before
                end of "Measurement Period"
          )
ELM XML Content |
    Encoded data (65576 characters)
ELM JSON Content |
    Encoded data (117184 characters)
Generated using version 0.4.9 of the sample-content-ig Liquid templates