Quality Measure Implementation Guide
1.0.0 - STU 1 International flag

This page is part of the Quality Measure Implementation Guide (v1.0.0: STU 1) based on FHIR (HL7® FHIR® Standard) R4. This is the current published version. For a full list of available versions, see the Directory of published versions

Library: BCS Component Library

Official URL: http://hl7.org/fhir/uv/cqm/Library/BCSComponent Version: 0.0.001
Standards status: Trial-use Maturity Level: 4 Computable Name: BCSComponent
Other Identifiers: OID:2.16.840.1.113883.4.642.40.61.28.4

This library is the primary measure library for the Breast Cancer Screening component of the composite measure examples in this implementation guide.

Metadata
Title BCS Component Library
Version 0.0.001
Identifier urn:oid:2.16.840.1.113883.4.642.40.61.28.4
Status Draft
Jurisdiction Global (Whole world)
Steward (Publisher) HL7 International / Clinical Quality Information
Description

This library is the primary measure library for the Breast Cancer Screening component of the composite measure examples in this implementation guide.
Type Logic Library
Parameter Name: Measurement Period
Use: In
Min Cardinality: 0
Max Cardinality: 1
Type: Period
Parameter Name: Patient
Use: Out
Min Cardinality: 0
Max Cardinality: 1
Type: Patient
Parameter Name: SDE Ethnicity
Use: Out
Min Cardinality: 0
Max Cardinality: *
Type: Coding
Parameter Name: SDE Payer
Use: Out
Min Cardinality: 0
Max Cardinality: *
Type: Resource
Parameter Name: SDE Race
Use: Out
Min Cardinality: 0
Max Cardinality: *
Type: Coding
Parameter Name: SDE Sex
Use: Out
Min Cardinality: 0
Max Cardinality: 1
Type: Coding
Parameter Name: Initial Population
Use: Out
Min Cardinality: 0
Max Cardinality: 1
Type: boolean
Parameter Name: Denominator
Use: Out
Min Cardinality: 0
Max Cardinality: 1
Type: boolean
Parameter Name: Right Mastectomy Diagnosis
Use: Out
Min Cardinality: 0
Max Cardinality: *
Type: Condition
Parameter Name: Right Mastectomy Procedure
Use: Out
Min Cardinality: 0
Max Cardinality: *
Type: Procedure
Parameter Name: Left Mastectomy Procedure
Use: Out
Min Cardinality: 0
Max Cardinality: *
Type: Procedure
Parameter Name: Bilateral Mastectomy Diagnosis
Use: Out
Min Cardinality: 0
Max Cardinality: *
Type: Condition
Parameter Name: Bilateral Mastectomy Procedure
Use: Out
Min Cardinality: 0
Max Cardinality: *
Type: Procedure
Parameter Name: Numerator
Use: Out
Min Cardinality: 0
Max Cardinality: 1
Type: boolean
Parameter Name: Left Mastectomy
Use: Out
Min Cardinality: 0
Max Cardinality: *
Type: Condition
Parameter Name: Denominator Exclusion
Use: Out
Min Cardinality: 0
Max Cardinality: 1
Type: boolean
Data Requirement Type: Patient
Profile(s): Patient
Data Requirement Type: Condition
Profile(s): Condition
Must Support Elements: code, onset
Code Filter(s):
Path: code
ValueSet: Status Post Right Mastectomy
Data Requirement Type: Condition
Profile(s): Condition
Must Support Elements: code, onset
Code Filter(s):
Path: code
ValueSet: History of bilateral mastectomy
Data Requirement Type: Condition
Profile(s): Condition
Must Support Elements: code, onset
Code Filter(s):
Path: code
ValueSet: Status Post Left Mastectomy
Data Requirement Type: Condition
Profile(s): Condition
Must Support Elements: code, bodySite, onset
Code Filter(s):
Path: code
ValueSet: Unilateral Mastectomy, Unspecified Laterality
Data Requirement Type: Procedure
Profile(s): Procedure
Must Support Elements: code, performed, status
Code Filter(s):
Path: code
ValueSet: Unilateral Mastectomy Right
Data Requirement Type: Procedure
Profile(s): Procedure
Must Support Elements: code, performed, status
Code Filter(s):
Path: code
ValueSet: Unilateral Mastectomy Left
Data Requirement Type: Procedure
Profile(s): Procedure
Must Support Elements: code, performed, status
Code Filter(s):
Path: code
ValueSet: Bilateral Mastectomy
Data Requirement Type: DiagnosticReport
Profile(s): DiagnosticReport
Must Support Elements: code, effective, status
Code Filter(s):
Path: code
ValueSet: Mammography
Library Content
CQL Content 
/*
This example is a work in progress and should not be considered a final specification
or recommendation for guidance. This example will help guide and direct the process
of finding conventions and usage patterns that meet the needs of the various stakeholders
in the measure development community.
*/
library BCSComponent version '0.0.001'

using FHIR version '4.0.1'

include hl7.fhir.uv.cql.FHIRHelpers version '4.0.1' called FHIRHelpers

include SupplementalDataElements version '2.0.000' called SDE
include MATGlobalCommonFunctions version '5.0.000' called Global
include AdultOutpatientEncounters version '2.0.000' called AdultOutpatientEncounters
include Hospice version '2.0.000' called Hospice
include AdvancedIllnessandFrailtyExclusion version '5.12.000' called Frailty

codesystem "LOINC": 'http://loinc.org'
codesystem "SNOMEDCT": 'http://snomed.info/sct'

valueset "Bilateral Mastectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1005'
valueset "Ethnicity": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.837'
valueset "Female": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.560.100.2'
valueset "History of bilateral mastectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1068'
valueset "Left": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.122.12.1036'
valueset "Mammography": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1018'
valueset "ONC Administrative Sex": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113762.1.4.1'
valueset "Payer": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.3591'
valueset "Race": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.114222.4.11.836'
valueset "Right": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.122.12.1035'
valueset "Status Post Left Mastectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1069'
valueset "Status Post Right Mastectomy": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1070'
valueset "Unilateral Mastectomy Left": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1133'
valueset "Unilateral Mastectomy Right": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1134'
valueset "Unilateral Mastectomy, Unspecified Laterality": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1071'

code "Birth date": '21112-8' from "LOINC" display 'Birth date'
code "Left (qualifier value)": '7771000' from "SNOMEDCT" display 'Left (qualifier value)'
code "Right (qualifier value)": '24028007' from "SNOMEDCT" display 'Right (qualifier value)'

parameter "Measurement Period" Interval<DateTime>

context Patient

define "SDE Ethnicity":
  SDE."SDE Ethnicity"

define "SDE Payer":
  SDE."SDE Payer"

define "SDE Race":
  SDE."SDE Race"

define "SDE Sex":
  SDE."SDE Sex"

define "Initial Population":
  Patient.gender = 'female'
      and Global."CalendarAgeInYearsAt" ( FHIRHelpers.ToDate ( Patient.birthDate ), start of "Measurement Period" ) in Interval[51, 74 )
      and exists AdultOutpatientEncounters."Qualifying Encounters"

define "Denominator":
  "Initial Population"

define "Right Mastectomy Diagnosis":
  ( ( [Condition: "Status Post Right Mastectomy"] )
      union ( [Condition: "Unilateral Mastectomy, Unspecified Laterality"] UnilateralMastectomyDiagnosis
          where UnilateralMastectomyDiagnosis.bodySite in "Right"
      ) ) RightMastectomy
      where Global."Normalize Interval" ( RightMastectomy.onset ) starts on or before
      end of "Measurement Period"

define "Right Mastectomy Procedure":
  [Procedure: "Unilateral Mastectomy Right"] UnilateralMastectomyRightPerformed
      where Global."Normalize Interval" ( UnilateralMastectomyRightPerformed.performed ) ends on or before
      end of "Measurement Period"
        and UnilateralMastectomyRightPerformed.status = 'completed'

define "Left Mastectomy Procedure":
  [Procedure: "Unilateral Mastectomy Left"] UnilateralMastectomyLeftPerformed
      where Global."Normalize Interval" ( UnilateralMastectomyLeftPerformed.performed ) ends on or before
      end of "Measurement Period"
        and UnilateralMastectomyLeftPerformed.status = 'completed'

define "Bilateral Mastectomy Diagnosis":
  [Condition: "History of bilateral mastectomy"] BilateralMastectomyHistory
      where Global."Normalize Interval" ( BilateralMastectomyHistory.onset ) starts on or before
      end of "Measurement Period"

define "Bilateral Mastectomy Procedure":
  [Procedure: "Bilateral Mastectomy"] BilateralMastectomyPerformed
      where Global."Normalize Interval" ( BilateralMastectomyPerformed.performed ) ends on or before
      end of "Measurement Period"
        and BilateralMastectomyPerformed.status = 'completed'

define "Numerator":
  exists ( [DiagnosticReport: "Mammography"] Mammogram
        where ( Global."Normalize Interval" ( Mammogram.effective ) ends 27 months or less on or before
          end of "Measurement Period"
        )
          and Mammogram.status in { 'final', 'amended', 'corrected', 'appended' }
    )

define "Denominator Exclusion":
  Hospice."Has Hospice"
      or ( ( exists "Right Mastectomy Diagnosis"
            or exists "Right Mastectomy Procedure"
        )
          and ( exists "Left Mastectomy"
              or exists "Left Mastectomy Procedure"
          )
      )
      or exists "Bilateral Mastectomy Diagnosis"
      or exists "Bilateral Mastectomy Procedure"
      or Frailty."Advanced Illness and Frailty Exclusion Not Including Over Age 80"
      or ( Global."CalendarAgeInYearsAt" ( FHIRHelpers.ToDate ( Patient.birthDate ), start of "Measurement Period" ) >= 65
          and Frailty."Long Term Care Periods Longer Than 90 Consecutive Days"
      )

define "Left Mastectomy":
  ( ( [Condition: "Status Post Left Mastectomy"] )
      union ( [Condition: "Unilateral Mastectomy, Unspecified Laterality"] UnilateralMastectomyDiagnosis
          where UnilateralMastectomyDiagnosis.bodySite in "Left"
      ) ) LeftMastectomy
      where Global."Normalize Interval" ( LeftMastectomy.onset ) starts on or before
      end of "Measurement Period"
ELM XML Content 
Encoded data (111544 characters)
ELM JSON Content 
Encoded data (203656 characters)
Generated using version 0.4.9 of the sample-content-ig Liquid templates