Clinical Practice Guidelines
2.0.0 - STU2 International flag

This page is part of the Clinical Guidelines (v2.0.0: STU2) based on FHIR (HL7® FHIR® Standard) R4. This is the current published version. For a full list of available versions, see the Directory of published versions

Library: Hold Medication Library (Experimental)

Official URL: http://hl7.org/fhir/uv/cpg/Library/holdmedication-library Version: 2.0.0
Active as of 2024-11-26 Computable Name: HoldMedicationLibrary
Other Identifiers: OID:2.16.840.1.113883.4.642.40.48.28.11

Logic for an example recommendation to hold a medication

Generated Narrative: Library holdmedication-library

Related Artifacts

Depends OnCode System Activity TypeCPG Activity Type Code System

Parameters

Patientout01Patient
Medication Orderout0*MedicationRequest
Inclusion Criteriaout01boolean
Hold Medication Proposalout0*Task
Is Recommendation Applicableout01boolean

Data Requirements

Type: MedicationRequest (MedicationRequest)
Type: Task (Task)

Contents

text/cql

library HoldMedication

using FHIR version '4.0.1'

include FHIRHelpers version '4.0.1'

codesystem "Activity Type": 'http://hl7.org/fhir/uv/cpg/CodeSystem/cpg-activity-type-cs'

code "Hold Activity": 'hold-activity' from "Activity Type"

context Patient

/* Recommendation to hold an existing order for a medication */

/*
Positive recommendation:

If an active order for the medication exists
  Propose holding the medication

Given a proposal, the user can:
  Accept the proposal
  Ignore the proposal
  Reject the proposal without reason
  Reject the proposal with reason

Scenario 1: Active medication order, no plan or proposal, decision support should propose
Scenario 2: Active medication order, incomplete proposal, decision support should not propose
Scenario 3: Active medication order, rejected proposal, decision support should not propose
Scenario 4: No active medication order, decision support should not propose

*/

define "Medication Order":
  [MedicationRequest] M
    where M.intent = 'order'
      and M.status = 'active'
      and M.doNotPerform is not true

define "Inclusion Criteria":
  Patient.active
    and exists "Medication Order"

define "Hold Medication Proposal":
  [Task] T
    where T.code ~ "Hold Activity"
      and doNotPerform(T) is not true

define "Is Recommendation Applicable":
  "Inclusion Criteria"
    and not exists "Hold Medication Proposal"

define function doNotPerform(task Task):
  singleton from (
    task.extension E
      where E.url = 'http://hl7.org/fhir/StructureDefinition/request-doNotPerform'
  ).value as boolean

Content not shown - (application/elm+xml, size = 21Kb )

Content not shown - (application/elm+json, size = 37Kb )