Quality Measure STU2 for FHIR R4 Implementation Guide

Quality Measure STU2 for FHIR R4 Implementation Guide

This page is part of the Quality Measure STU2 for FHIR R4 Implementation Guide (v2.0.0: STU 2) based on FHIR R4. The current version which supercedes this version is 3.0.0. For a full list of available versions, see the Directory of published versions

Bundle-exm-library-bundle

Formats: XML, JSON, Turtle

Bundle exm-library-bundle of type collection

Entry 1

Resource Library:

Id: EXM124

Url: http://hl7.org/fhir/us/cqfmeasures/Library/EXM124

Version: 9.0.000

Identifier:
value: EXM124

Name: EXM124

Title: Cervical Cancer Screening

Status: active

Experimental: true

Type:
system: http://terminology.hl7.org/CodeSystem/library-type

code: logic-library

Date: 2019-09-03T00:00:00-06:00

Publisher: Health Level 7 International - Clinical Quality Information Work Group

Description: This library is used as an example in the FHIR Quality Measure Implementation Guide

Use Context:

code value

program ep-ec

Jurisdiction: US

Approval Date: 2019-08-03

Last Review Date: 2019-08-03

Related Artifacts:

Type Resource

depends-on http://hl7.org/fhir/Library/FHIR-ModelInfo|4.0.1

depends-on http://hl7.org/fhir/Library/FHIRHelpers|4.0.1

depends-on http://hl7.org/fhir/us/cqfmeasures/Library/Hospice|2.0.000

depends-on http://hl7.org/fhir/us/cqfmeasures/Library/AdultOutpatientEncounters|2.0.000

depends-on http://hl7.org/fhir/us/cqfmeasures/Library/MATGlobalCommonFunctions|5.0.000

depends-on http://hl7.org/fhir/us/cqfmeasures/Library/SupplementalDataElements|2.0.0

depends-on http://snomed.info/sct|http://snomed.info/sct/731000124108/version/201709

depends-on http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1014

depends-on http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1017

depends-on http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.110.12.1059

Parameters:

Name Type Min Max In/Out

Measurement Period Period 0 1 in

Patient Patient 0 1 out

SDE Ethnicity Coding 0 * out

SDE Payer Any 0 * out

SDE Race Coding 0 * out

SDE Sex Coding 0 1 out

Initial Population boolean 0 1 out

Denominator boolean 0 1 out

Absence of Cervix Any 0 * out

Denominator Exclusion boolean 0 1 out

Cervical Cytology Within 3 Years Observation 0 * out

HPV Test Within 5 Years for Women Age 30 and Older Observation 0 * out

Numerator boolean 0 1 out

Data Requirements:

Type Profile MS Code Filter

Procedure http://hl7.org/fhir/StructureDefinition/Procedure
code filter:
path: code
value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1014

Condition http://hl7.org/fhir/StructureDefinition/Condition
code filter:
path: code

system: http://snomed.info/sct

code: 37687000

display: Congenital absence of cervix (disorder)

Observation http://hl7.org/fhir/StructureDefinition/Observation
code filter:
path: code
value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1017

Observation http://hl7.org/fhir/StructureDefinition/Observation
code filter:
path: code
value set: http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.110.12.1059
Content: text/cql
library EXM124 version '9.0.000'


/*
Based on CMS124v9 - Cervical Cancer Screening
*/

/*
This example is a work in progress and should not be considered a final specification
or recommendation for guidance. This example will help guide and direct the process
of finding conventions and usage patterns that meet the needs of the various stakeholders
in the measure development community.
*/

using FHIR version '4.0.1'

include FHIRHelpers version '4.0.1' called FHIRHelpers
include Hospice version '2.0.000' called Hospice
include AdultOutpatientEncounters version '2.0.000' called AdultOutpatientEncounters
include MATGlobalCommonFunctions version '5.0.000' called Global
include SupplementalDataElements version '2.0.0' called SDE

codesystem "SNOMEDCT:2017-09": 'http://snomed.info/sct' version 'http://snomed.info/sct/731000124108/version/201709'

valueset "Hysterectomy with No Residual Cervix": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1014'
valueset "Pap Test": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1017'
valueset "HPV Test": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.110.12.1059'

code "Congenital absence of cervix (disorder)": '37687000' from "SNOMEDCT:2017-09" display 'Congenital absence of cervix (disorder)'

parameter "Measurement Period" Interval<DateTime>
  default Interval[@2019-01-01T00:00:00.0, @2020-01-01T00:00:00.0)

context Patient

define "SDE Ethnicity":
  SDE."SDE Ethnicity"

define "SDE Payer":
  SDE."SDE Payer"

define "SDE Race":
  SDE."SDE Race"

define "SDE Sex":
  SDE."SDE Sex"

define "Initial Population":
	Patient.gender = 'female'
		and Global."CalendarAgeInYearsAt"(FHIRHelpers.ToDate(Patient.birthDate), start of "Measurement Period") in Interval[23, 64]
		and exists AdultOutpatientEncounters."Qualifying Encounters"

define "Denominator":
	"Initial Population"

define "Denominator Exclusion":
	Hospice."Has Hospice"
		or exists "Absence of Cervix"

define "Absence of Cervix":
  ([Procedure: "Hysterectomy with No Residual Cervix"] NoCervixProcedure
   where Global."Normalize Interval"(NoCervixProcedure.performed) ends on or before end of "Measurement Period"
     and NoCervixProcedure.status = 'completed'
     )
  union [Condition : "Congenital absence of cervix (disorder)"] NoCervixBirth
		where Global."Normalize Interval"(NoCervixBirth.onset) starts on or before end of "Measurement Period"
  //    and NoCervixBirth.clinicalStatus ~ ToConcept(Global."active") because this is an excluion, all statuses are acceptable

define "Numerator":
	exists "Cervical Cytology Within 3 Years"
		or exists "HPV Test Within 5 Years for Women Age 30 and Older"

define "Cervical Cytology Within 3 Years":
	[Observation: "Pap Test"] CervicalCytology
		where CervicalCytology.value is not null
			and CervicalCytology.status in { 'final', 'amended', 'corrected', 'preliminary' }
		  and Global."Normalize Interval"(CervicalCytology.effective) ends 3 years or less on or before end of "Measurement Period"

define "HPV Test Within 5 Years for Women Age 30 and Older":
	[Observation: "HPV Test"] HPVTest
      where HPVTest.value is not null
        and HPVTest.status in { 'final', 'amended', 'corrected', 'preliminary' }
        and  Global."CalendarAgeInYearsAt"(FHIRHelpers.ToDate(Patient.birthDate), start of Global."Normalize Interval"(HPVTest.effective))>= 30
        and Global."Normalize Interval"(HPVTest.effective) ends 5 years or less on or before end of "Measurement Period"
Content: application/elm+xml
Encoded data (29760 characters)
Content: application/elm+json
Encoded data (54228 characters)

Content: text/cql
library EXM124 version '9.0.000' /* Based on CMS124v9 - Cervical Cancer Screening / / This example is a work in progress and should not be considered a final specification or recommendation for guidance. This example will help guide and direct the process of finding conventions and usage patterns that meet the needs of the various stakeholders in the measure development community. */ using FHIR version '4.0.1' include FHIRHelpers version '4.0.1' called FHIRHelpers include Hospice version '2.0.000' called Hospice include AdultOutpatientEncounters version '2.0.000' called AdultOutpatientEncounters include MATGlobalCommonFunctions version '5.0.000' called Global include SupplementalDataElements version '2.0.0' called SDE codesystem "SNOMEDCT:2017-09": 'http://snomed.info/sct' version 'http://snomed.info/sct/731000124108/version/201709' valueset "Hysterectomy with No Residual Cervix": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.198.12.1014' valueset "Pap Test": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.108.12.1017' valueset "HPV Test": 'http://cts.nlm.nih.gov/fhir/ValueSet/2.16.840.1.113883.3.464.1003.110.12.1059' code "Congenital absence of cervix (disorder)": '37687000' from "SNOMEDCT:2017-09" display 'Congenital absence of cervix (disorder)' parameter "Measurement Period" Interval<DateTime> default Interval[@2019-01-01T00:00:00.0, @2020-01-01T00:00:00.0) context Patient define "SDE Ethnicity": SDE."SDE Ethnicity" define "SDE Payer": SDE."SDE Payer" define "SDE Race": SDE."SDE Race" define "SDE Sex": SDE."SDE Sex" define "Initial Population": Patient.gender = 'female' and Global."CalendarAgeInYearsAt"(FHIRHelpers.ToDate(Patient.birthDate), start of "Measurement Period") in Interval[23, 64] and exists AdultOutpatientEncounters."Qualifying Encounters" define "Denominator": "Initial Population" define "Denominator Exclusion": Hospice."Has Hospice" or exists "Absence of Cervix" define "Absence of Cervix": ([Procedure: "Hysterectomy with No Residual Cervix"] NoCervixProcedure where Global."Normalize Interval"(NoCervixProcedure.performed) ends on or before end of "Measurement Period" and NoCervixProcedure.status = 'completed' ) union [Condition : "Congenital absence of cervix (disorder)"] NoCervixBirth where Global."Normalize Interval"(NoCervixBirth.onset) starts on or before end of "Measurement Period" // and NoCervixBirth.clinicalStatus ~ ToConcept(Global."active") because this is an excluion, all statuses are acceptable define "Numerator": exists "Cervical Cytology Within 3 Years" or exists "HPV Test Within 5 Years for Women Age 30 and Older" define "Cervical Cytology Within 3 Years": [Observation: "Pap Test"] CervicalCytology where CervicalCytology.value is not null and CervicalCytology.status in { 'final', 'amended', 'corrected', 'preliminary' } and Global."Normalize Interval"(CervicalCytology.effective) ends 3 years or less on or before end of "Measurement Period" define "HPV Test Within 5 Years for Women Age 30 and Older": [Observation: "HPV Test"] HPVTest where HPVTest.value is not null and HPVTest.status in { 'final', 'amended', 'corrected', 'preliminary' } and Global."CalendarAgeInYearsAt"(FHIRHelpers.ToDate(Patient.birthDate), start of Global."Normalize Interval"(HPVTest.effective))>= 30 and Global."Normalize Interval"(HPVTest.effective) ends 5 years or less on or before end of "Measurement Period"

Content: application/elm+xml
`Encoded data (29760 characters)`

Content: application/elm+json
`Encoded data (54228 characters)`