FHIR Extensions Pack
5.1.0 - 5.1.0 (April 2024) International flag

This page is part of the FHIR Core Extensions Registry (v5.1.0: Release 5.1) based on FHIR (HL7® FHIR® Standard) v5.0.0. This is the current published version. For a full list of available versions, see the Directory of published versions

StructureMap: FML Conversion for Provenance: R5 to R4B

Official URL: http://hl7.org/fhir/StructureMap/Provenance5to4B Version: 5.1.0
Standards status: Trial-use Maturity Level: 1 Computable Name: Provenance5to4B

FMLConversionforProvenanceR5toR4B

/// url = 'http://hl7.org/fhir/StructureMap/Provenance5to4B'
/// name = 'Provenance5to4B'
/// title = 'FML Conversion for Provenance: R5 to R4B'
/// status = 'active'

conceptmap "ProvenanceEntityRole" {
  prefix s = "http://hl7.org/fhir/provenance-entity-role"
  prefix t = "http://hl7.org/fhir/4.3/provenance-entity-role"

  s:revision - t:revision
  s:quotation - t:quotation
  s:source - t:source
  s:removal - t:removal
}

uses "http://hl7.org/fhir/StructureDefinition/Provenance" alias ProvenanceR5 as source
uses "http://hl7.org/fhir/4.3/StructureDefinition/Provenance" alias ProvenanceR4B as target

imports "http://hl7.org/fhir/StructureMap/*5to4B"

group Provenance(source src : ProvenanceR5, target tgt : ProvenanceR4B) extends DomainResource <<type+>> {
  src.target -> tgt.target;
  src.occurred : Period -> tgt.occurred;
  src.occurred : dateTime -> tgt.occurred;
  src.recorded -> tgt.recorded;
  src.policy -> tgt.policy;
  src.location -> tgt.location;
  src.activity -> tgt.activity; // src.authorization -> tgt.authorization;
  src.agent as s -> tgt.agent as t then ProvenanceAgent(s, t); // src.basedOn -> tgt.basedOn;
  src.entity as s -> tgt.entity as t then ProvenanceEntity(s, t);
  src.signature -> tgt.signature;
}

group ProvenanceAgent(source src, target tgt) extends BackboneElement {
  src.type -> tgt.type;
  src.role -> tgt.role;
  src.who -> tgt.who;
  src.onBehalfOf -> tgt.onBehalfOf;
}

group ProvenanceEntity(source src, target tgt) extends BackboneElement {
  src.role as v -> tgt.role = translate(v, '#ProvenanceEntityRole', 'code');
  src.what -> tgt.what;
}