FHIR Extensions Pack
5.1.0 - 5.1.0 (April 2024) International flag

This page is part of the FHIR Core Extensions Registry (v5.1.0: Release 5.1) based on FHIR (HL7® FHIR® Standard) v5.0.0. This is the current published version. For a full list of available versions, see the Directory of published versions

StructureMap: FML Conversion for Medication: R5 to R4

Official URL: http://hl7.org/fhir/StructureMap/Medication5to4 Version: 5.1.0
Standards status: Trial-use Maturity Level: 1 Computable Name: Medication5to4

FMLConversionforMedicationR5toR4

/// url = 'http://hl7.org/fhir/StructureMap/Medication5to4'
/// name = 'Medication5to4'
/// title = 'FML Conversion for Medication: R5 to R4'
/// status = 'active'

conceptmap "MedicationStatus" {
  prefix s = "http://hl7.org/fhir/CodeSystem/medication-status"
  prefix t = "http://hl7.org/fhir/4.0/CodeSystem/medication-status"

  s:active - t:active
  s:inactive - t:inactive
  s:"entered-in-error" - t:"entered-in-error"
}

uses "http://hl7.org/fhir/StructureDefinition/Medication" alias MedicationR5 as source
uses "http://hl7.org/fhir/4.0/StructureDefinition/Medication" alias MedicationR4 as target

imports "http://hl7.org/fhir/StructureMap/*5to4"

group Medication(source src : MedicationR5, target tgt : MedicationR4) extends DomainResource <<type+>> {
  src.identifier -> tgt.identifier;
  src.code -> tgt.code;
  src.status as v -> tgt.status = translate(v, '#MedicationStatus', 'code');
  src.marketingAuthorizationHolder -> tgt.manufacturer;
  src.doseForm -> tgt.form;
  src.totalVolume as s ->  tgt.amount as t,  t.numerator = s;
  src.ingredient as s -> tgt.ingredient as t then MedicationIngredient(s, t);
  src.batch as s -> tgt.batch as t then MedicationBatch(s, t);
}

group MedicationIngredient(source src, target tgt) extends BackboneElement {
  src.item -> tgt.item;
  src.isActive -> tgt.isActive;
  src.strength : Ratio -> tgt.strength;
}

group MedicationBatch(source src, target tgt) extends BackboneElement {
  src.lotNumber -> tgt.lotNumber;
  src.expirationDate -> tgt.expirationDate;
}