/// url = 'http://hl7.org/fhir/StructureMap/ManufacturedItemDefinition5to4B'
/// name = 'ManufacturedItemDefinition5to4B'
/// title = 'FML Conversion for ManufacturedItemDefinition: R5 to R4B'
/// status = 'active'

conceptmap "PublicationStatus" {
  prefix s = "http://hl7.org/fhir/publication-status"
  prefix t = "http://hl7.org/fhir/4.3/publication-status"

  s:draft - t:draft
  s:active - t:active
  s:retired - t:retired
  s:unknown - t:unknown
}

uses "http://hl7.org/fhir/StructureDefinition/ManufacturedItemDefinition" alias ManufacturedItemDefinitionR5 as source
uses "http://hl7.org/fhir/4.3/StructureDefinition/ManufacturedItemDefinition" alias ManufacturedItemDefinitionR4B as target

imports "http://hl7.org/fhir/StructureMap/*5to4B"

group ManufacturedItemDefinition(source src : ManufacturedItemDefinitionR5, target tgt : ManufacturedItemDefinitionR4B) extends DomainResource <<type+>> {
  src.identifier -> tgt.identifier;
  src.status as v -> tgt.status = translate(v, '#PublicationStatus', 'code');
  src.manufacturedDoseForm -> tgt.manufacturedDoseForm; // src.name -> tgt.name;
  src.unitOfPresentation -> tgt.unitOfPresentation;
  src.manufacturer -> tgt.manufacturer;
  src.ingredient -> tgt.ingredient; // src.marketingStatus -> tgt.marketingStatus;
  src.property as s -> tgt.property as t then ManufacturedItemDefinitionProperty(s, t);
}

group ManufacturedItemDefinitionProperty(source src, target tgt) extends BackboneElement {
  src.type -> tgt.type;
  src.value : CodeableConcept -> tgt.value;
  src.value : Quantity -> tgt.value;
  src.value : date -> tgt.value;
  src.value : boolean -> tgt.value;
  src.value : Attachment -> tgt.value; // src.value : markdown -> tgt.value;
}