/// url = 'http://hl7.org/fhir/StructureMap/EpisodeOfCare5to4B'
/// name = 'EpisodeOfCare5to4B'
/// title = 'FML Conversion for EpisodeOfCare: R5 to R4B'
/// status = 'active'

conceptmap "EpisodeOfCareStatus" {
  prefix s = "http://hl7.org/fhir/episode-of-care-status"
  prefix t = "http://hl7.org/fhir/4.3/episode-of-care-status"

  s:planned - t:planned
  s:waitlist - t:waitlist
  s:active - t:active
  s:onhold - t:onhold
  s:finished - t:finished
  s:cancelled - t:cancelled
  s:"entered-in-error" - t:"entered-in-error"
}

uses "http://hl7.org/fhir/StructureDefinition/EpisodeOfCare" alias EpisodeOfCareR5 as source
uses "http://hl7.org/fhir/4.3/StructureDefinition/EpisodeOfCare" alias EpisodeOfCareR4B as target

imports "http://hl7.org/fhir/StructureMap/*5to4B"

group EpisodeOfCare(source src : EpisodeOfCareR5, target tgt : EpisodeOfCareR4B) extends DomainResource <<type+>> {
  src.identifier -> tgt.identifier;
  src.status as v -> tgt.status = translate(v, '#EpisodeOfCareStatus', 'code');
  src.statusHistory as s -> tgt.statusHistory as t then EpisodeOfCareStatusHistory(s, t);
  src.type -> tgt.type;
  src.diagnosis as s -> tgt.diagnosis as t then EpisodeOfCareDiagnosis(s, t); // src.reason as s -> tgt.reason as t then EpisodeOfCareReason(s,t);
  src.patient -> tgt.patient;
  src.managingOrganization -> tgt.managingOrganization;
  src.period -> tgt.period;
  src.referralRequest -> tgt.referralRequest;
  src.careManager -> tgt.careManager;
  src.careTeam -> tgt.team;
  src.account -> tgt.account;
}

group EpisodeOfCareStatusHistory(source src, target tgt) extends BackboneElement {
  src.status as v -> tgt.status = translate(v, '#EpisodeOfCareStatus', 'code');
  src.period -> tgt.period;
}

// group EpisodeOfCareReason(source src, target tgt) extends BackboneElement {
// src.use -> tgt.use;
// src.value -> tgt.value;
// }
group EpisodeOfCareDiagnosis(source src, target tgt) extends BackboneElement {
  src.condition -> tgt.condition;
  src.use -> tgt.role;
}