/// url = 'http://hl7.org/fhir/StructureMap/ChargeItem5to4'
/// name = 'ChargeItem5to4'
/// title = 'FML Conversion for ChargeItem: R5 to R4'
/// status = 'active'

conceptmap "ChargeItemStatus" {
  prefix s = "http://hl7.org/fhir/chargeitem-status"
  prefix t = "http://hl7.org/fhir/4.0/chargeitem-status"

  s:planned - t:planned
  s:billable - t:billable
  s:"not-billable" - t:"not-billable"
  s:aborted - t:aborted
  s:billed - t:billed
  s:"entered-in-error" - t:"entered-in-error"
  s:unknown - t:unknown
}

uses "http://hl7.org/fhir/StructureDefinition/ChargeItem" alias ChargeItemR5 as source
uses "http://hl7.org/fhir/4.0/StructureDefinition/ChargeItem" alias ChargeItemR4 as target

imports "http://hl7.org/fhir/StructureMap/*5to4"

group ChargeItem(source src : ChargeItemR5, target tgt : ChargeItemR4) extends DomainResource <<type+>> {
  src.identifier -> tgt.identifier;
  src.definitionUri -> tgt.definitionUri;
  src.definitionCanonical -> tgt.definitionCanonical;
  src.status as v -> tgt.status = translate(v, '#ChargeItemStatus', 'code');
  src.partOf -> tgt.partOf;
  src.code -> tgt.code;
  src.subject -> tgt.subject;
  src.encounter -> tgt.context;
  src.occurrence : dateTime -> tgt.occurrence;
  src.occurrence : Period -> tgt.occurrence;
  src.occurrence : Timing -> tgt.occurrence;
  src.performer as s -> tgt.performer as t then ChargeItemPerformer(s, t);
  src.performingOrganization -> tgt.performingOrganization;
  src.requestingOrganization -> tgt.requestingOrganization;
  src.costCenter -> tgt.costCenter;
  src.quantity -> tgt.quantity;
  src.bodysite -> tgt.bodysite;
  src.totalPriceComponent as s -> tgt then {
    s.amount -> tgt.priceOverride;
  };
  src.overrideReason -> tgt.overrideReason;
  src.enterer -> tgt.enterer;
  src.enteredDate -> tgt.enteredDate;
  src.reason -> tgt.reason;
  src.service -> tgt.service;
  src.product -> tgt.product;
  src.account -> tgt.account;
  src.note -> tgt.note;
  src.supportingInformation -> tgt.supportingInformation;
}

group ChargeItemPerformer(source src, target tgt) extends BackboneElement {
  src.function -> tgt.function;
  src.actor -> tgt.actor;
}