/// url = 'http://hl7.org/fhir/StructureMap/VisionPrescription5to4B'
/// name = 'VisionPrescription5to4B'
/// title = 'FML Conversion for VisionPrescription: R5 to R4B'
/// status = 'active'

conceptmap "VisionBase" {
  prefix s = "http://hl7.org/fhir/vision-base-codes"
  prefix t = "http://hl7.org/fhir/4.3/vision-base-codes"

  s:up - t:up
  s:down - t:down
  s:in - t:in
  s:out - t:out
}

conceptmap "VisionEyes" {
  prefix s = "http://hl7.org/fhir/vision-eye-codes"
  prefix t = "http://hl7.org/fhir/4.3/vision-eye-codes"

  s:right - t:right
  s:left - t:left
}

conceptmap "VisionStatus" {
  prefix s = "http://hl7.org/fhir/fm-status"
  prefix t = "http://hl7.org/fhir/4.3/fm-status"

  s:active - t:active
  s:cancelled - t:cancelled
  s:draft - t:draft
  s:"entered-in-error" - t:"entered-in-error"
}

uses "http://hl7.org/fhir/StructureDefinition/VisionPrescription" alias VisionPrescriptionR5 as source
uses "http://hl7.org/fhir/4.3/StructureDefinition/VisionPrescription" alias VisionPrescriptionR4B as target

imports "http://hl7.org/fhir/StructureMap/*5to4B"

group VisionPrescription(source src : VisionPrescriptionR5, target tgt : VisionPrescriptionR4B) extends DomainResource <<type+>> {
  src.identifier -> tgt.identifier;
  src.status as v -> tgt.status = translate(v, '#VisionStatus', 'code');
  src.created -> tgt.created;
  src.patient -> tgt.patient;
  src.encounter -> tgt.encounter;
  src.dateWritten -> tgt.dateWritten;
  src.prescriber -> tgt.prescriber;
  src.lensSpecification as s -> tgt.lensSpecification as t then VisionPrescriptionLensSpecification(s, t);
}

group VisionPrescriptionLensSpecification(source src, target tgt) extends BackboneElement {
  src.product -> tgt.product;
  src.eye as v -> tgt.eye = translate(v, '#VisionEyes', 'code');
  src.sphere -> tgt.sphere;
  src.cylinder -> tgt.cylinder;
  src.axis -> tgt.axis;
  src.prism as s -> tgt.prism as t then VisionPrescriptionLensSpecificationPrism(s, t);
  src.add -> tgt.add;
  src.power -> tgt.power;
  src.backCurve -> tgt.backCurve;
  src.diameter -> tgt.diameter;
  src.duration -> tgt.duration;
  src.color -> tgt.color;
  src.brand -> tgt.brand;
  src.note -> tgt.note;
}

group VisionPrescriptionLensSpecificationPrism(source src, target tgt) extends BackboneElement {
  src.amount -> tgt.amount;
  src.base as v -> tgt.base = translate(v, '#VisionBase', 'code');
}