/// url = 'http://hl7.org/fhir/StructureMap/ServiceRequest4to5'
/// name = 'ServiceRequest4to5'
/// title = 'FML Conversion for ServiceRequest: R4 to R5'
/// status = 'active'

conceptmap "ServiceRequestIntent" {
  prefix s = "http://hl7.org/fhir/4.0/request-intent"
  prefix t = "http://hl7.org/fhir/request-intent"

  s:proposal - t:proposal
  s:plan - t:plan
  s:directive - t:directive
  s:order - t:order
  s:"original-order" - t:"original-order"
  s:"reflex-order" - t:"reflex-order"
  s:"filler-order" - t:"filler-order"
  s:"instance-order" - t:"instance-order"
  s:option - t:option
}

conceptmap "ServiceRequestPriority" {
  prefix s = "http://hl7.org/fhir/4.0/request-priority"
  prefix t = "http://hl7.org/fhir/request-priority"

  s:routine - t:routine
  s:urgent - t:urgent
  s:asap - t:asap
  s:stat - t:stat
}

conceptmap "ServiceRequestStatus" {
  prefix s = "http://hl7.org/fhir/4.0/request-status"
  prefix t = "http://hl7.org/fhir/request-status"

  s:draft - t:draft
  s:active - t:active
  s:"on-hold" - t:"on-hold"
  s:revoked - t:revoked
  s:completed - t:completed
  s:"entered-in-error" - t:"entered-in-error"
  s:unknown - t:unknown
}

uses "http://hl7.org/fhir/4.0/StructureDefinition/ServiceRequest" alias ServiceRequestR4 as source
uses "http://hl7.org/fhir/StructureDefinition/ServiceRequest" alias ServiceRequestR5 as target

imports "http://hl7.org/fhir/StructureMap/*4to5"

group ServiceRequest(source src : ServiceRequestR4, target tgt : ServiceRequestR5) extends DomainResource <<type+>> {
  src.identifier -> tgt.identifier;
  src.instantiatesCanonical -> tgt.instantiatesCanonical;
  src.instantiatesUri -> tgt.instantiatesUri;
  src.basedOn -> tgt.basedOn;
  src.replaces -> tgt.replaces;
  src.requisition -> tgt.requisition;
  src.status as v -> tgt.status = translate(v, '#ServiceRequestStatus', 'code');
  src.intent as v -> tgt.intent = translate(v, '#ServiceRequestIntent', 'code');
  src.category -> tgt.category;
  src.priority as v -> tgt.priority = translate(v, '#ServiceRequestPriority', 'code');
  src.doNotPerform -> tgt.doNotPerform;
  src.code : CodeableConcept -> tgt.code;
  src.orderDetail : CodeableConcept as s ->  tgt.orderDetail as t,  t.parameterFocus = s;
  src.quantity : Quantity -> tgt.quantity;
  src.quantity : Ratio -> tgt.quantity;
  src.quantity : Range -> tgt.quantity;
  src.subject -> tgt.subject;
  src.encounter -> tgt.encounter; // src.focus -> tgt.focus;
  src.occurrence : dateTime -> tgt.occurrence;
  src.occurrence : Period -> tgt.occurrence;
  src.occurrence : Timing -> tgt.occurrence;
  src.asNeeded : boolean -> tgt.asNeeded;
  src.asNeeded : CodeableConcept -> tgt.asNeeded;
  src.authoredOn -> tgt.authoredOn;
  src.requester -> tgt.requester;
  src.performerType -> tgt.performerType;
  src.performer -> tgt.performer;
  src.locationCode -> tgt.location;
  src.locationReference -> tgt.location;
  src.reasonCode -> tgt.reason;
  src.reasonReference -> tgt.reason;
  src.insurance -> tgt.insurance;
  src.supportingInfo -> tgt.supportingInfo;
  src.specimen -> tgt.specimen;
  src.bodySite -> tgt.bodySite;
  src.note -> tgt.note; // src.bodyStructure -> tgt.bodyStructure;
  src.patientInstruction : string as s ->  tgt.patientInstruction as t,  t.instruction = s "instruction";
  src.relevantHistory -> tgt.relevantHistory;
}