/// url = 'http://hl7.org/fhir/StructureMap/ImagingStudy4to5'
/// name = 'ImagingStudy4to5'
/// title = 'FML Conversion for ImagingStudy: R4 to R5'
/// status = 'active'

conceptmap "ImagingStudyStatus" {
  prefix s = "http://hl7.org/fhir/4.0/imagingstudy-status"
  prefix t = "http://hl7.org/fhir/imagingstudy-status"

  s:registered - t:registered
  s:available - t:available
  s:cancelled - t:cancelled
  s:"entered-in-error" - t:"entered-in-error"
  s:unknown - t:unknown
}

uses "http://hl7.org/fhir/4.0/StructureDefinition/ImagingStudy" alias ImagingStudyR4 as source
uses "http://hl7.org/fhir/StructureDefinition/ImagingStudy" alias ImagingStudyR5 as target

imports "http://hl7.org/fhir/StructureMap/*4to5"

group ImagingStudy(source src : ImagingStudyR4, target tgt : ImagingStudyR5) extends DomainResource <<type+>> {
  src.identifier -> tgt.identifier;
  src.status as v -> tgt.status = translate(v, '#ImagingStudyStatus', 'code');
  src.modality -> tgt.modality;
  src.subject -> tgt.subject;
  src.encounter -> tgt.encounter;
  src.started -> tgt.started;
  src.basedOn -> tgt.basedOn;
  src.referrer -> tgt.referrer; // src.partOf -> tgt.partOf;
  src.endpoint -> tgt.endpoint;
  src.numberOfSeries -> tgt.numberOfSeries;
  src.numberOfInstances -> tgt.numberOfInstances;
  src.procedureCode : CodeableConcept -> tgt.procedure;
  src.procedureReference : Reference -> tgt.procedure;
  src.location -> tgt.location;
  src.reasonCode : CodeableConcept -> tgt.reason;
  src.reasonReference : Reference -> tgt.reason;
  src.note -> tgt.note;
  src.description -> tgt.description;
  src.series as s -> tgt.series as t then ImagingStudySeries(s, t);
}

group ImagingStudySeries(source src, target tgt) extends BackboneElement {
  src.uid -> tgt.uid;
  src.number -> tgt.number;
  src.modality -> tgt.modality;
  src.description -> tgt.description;
  src.numberOfInstances -> tgt.numberOfInstances;
  src.endpoint -> tgt.endpoint;
  src.bodySite -> tgt.bodySite;
  src.laterality -> tgt.laterality;
  src.specimen -> tgt.specimen;
  src.started -> tgt.started;
  src.performer as s -> tgt.performer as t then ImagingStudySeriesPerformer(s, t);
  src.instance as s -> tgt.instance as t then ImagingStudySeriesInstance(s, t);
}

group ImagingStudySeriesPerformer(source src, target tgt) extends BackboneElement {
  src.function -> tgt.function;
  src.actor -> tgt.actor;
}

group ImagingStudySeriesInstance(source src, target tgt) extends BackboneElement {
  src.uid -> tgt.uid;
  src.sopClass -> tgt.sopClass;
  src.number -> tgt.number;
  src.title -> tgt.title;
}