/// url = 'http://hl7.org/fhir/StructureMap/Composition4Bto5'
/// name = 'Composition4Bto5'
/// title = 'FML Conversion for Composition: R4B to R5'
/// status = 'active'

conceptmap "CompositionStatus" {
  prefix s = "http://hl7.org/fhir/4.3/composition-status"
  prefix t = "http://hl7.org/fhir/composition-status"

  s:preliminary - t:preliminary
  s:final - t:final
  s:amended - t:amended
  s:"entered-in-error" - t:"entered-in-error"
}

uses "http://hl7.org/fhir/4.3/StructureDefinition/Composition" alias CompositionR4B as source
uses "http://hl7.org/fhir/StructureDefinition/Composition" alias CompositionR5 as target

imports "http://hl7.org/fhir/StructureMap/*4Bto5"

group Composition(source src : CompositionR4B, target tgt : CompositionR5) extends DomainResource <<type+>> {
  src.identifier -> tgt.identifier; // src.url -> tgt.url;
  src.status as v -> tgt.status = translate(v, '#CompositionStatus', 'code'); // src.version -> tgt.version;
  src.type -> tgt.type;
  src.category -> tgt.category;
  src.subject -> tgt.subject;
  src.encounter -> tgt.encounter;
  src.date -> tgt.date;
  src.author -> tgt.author; // src.useContext -> tgt.useContext;
  src.title -> tgt.title; // src.name -> tgt.name;
  src.attester as s -> tgt.attester as t then CompositionAttester(s, t); // src.note -> tgt.note;
  src.custodian -> tgt.custodian;
  src.relatesTo as s -> tgt.relatesTo as t then CompositionRelatesTo(s, t);
  src.event as s -> tgt.event as t then CompositionEvent(s, t);
  src.section as s -> tgt.section as t then CompositionSection(s, t);
}

group CompositionAttester(source src, target tgt) extends BackboneElement {
  src.mode as s ->  tgt.mode = create('CodeableConcept') as t,  t.coding = create('Coding') as tc,  tc.system = 'http://hl7.org/fhir/composition-attestation-mode',  tc.code = s;
  src.time -> tgt.time;
  src.party -> tgt.party;
}

group CompositionRelatesTo(source src, target tgt) extends Element {
  src.code -> tgt.type;
  src.target : Identifier as s ->  tgt.resourceReference as t,  t.identifier = s;
  src.target : Reference -> tgt.resourceReference;
}

group CompositionEvent(source src, target tgt) extends BackboneElement {
  src.period -> tgt.period; // src.code -> tgt.code;
  src.detail -> tgt.detail;
}

group CompositionSection(source src, target tgt) extends BackboneElement {
  src.title -> tgt.title;
  src.code -> tgt.code;
  src.author -> tgt.author;
  src.focus -> tgt.focus;
  src.text -> tgt.text;
  src.orderedBy -> tgt.orderedBy; // src.mode as v -> tgt.mode = translate(v, '#SectionMode', 'code');
  src.entry -> tgt.entry;
  src.emptyReason -> tgt.emptyReason;
}