FHIR Extensions Pack
5.1.0-snapshot1 - Working Copy International flag

This page is part of the FHIR Core Extensions Registry (v5.1.0-snapshot1: Release 5.1) based on FHIR (HL7® FHIR® Standard) v5.0.0. The current version which supersedes this version is 1.0.0. For a full list of available versions, see the Directory of published versions

StructureMap: FML Conversion for CareTeam: R4B to R5

Official URL: http://hl7.org/fhir/StructureMap/CareTeam4Bto5 Version: 5.1.0-snapshot1
Standards status: Trial-use Maturity Level: 1 Computable Name: CareTeam4Bto5

FMLConversionforCareTeamR4BtoR5

/// url = 'http://hl7.org/fhir/StructureMap/CareTeam4Bto5'
/// name = 'CareTeam4Bto5'
/// title = 'FML Conversion for CareTeam: R4B to R5'
/// status = 'active'

conceptmap "CareTeamStatus" {
  prefix s = "http://hl7.org/fhir/4.3/care-team-status"
  prefix t = "http://hl7.org/fhir/care-team-status"

  s:proposed - t:proposed
  s:active - t:active
  s:suspended - t:suspended
  s:inactive - t:inactive
  s:"entered-in-error" - t:"entered-in-error"
}

uses "http://hl7.org/fhir/4.3/StructureDefinition/CareTeam" alias CareTeamR4B as source
uses "http://hl7.org/fhir/StructureDefinition/CareTeam" alias CareTeamR5 as target

imports "http://hl7.org/fhir/StructureMap/*4Bto5"

group CareTeam(source src : CareTeamR4B, target tgt : CareTeamR5) extends DomainResource <<type+>> {
  src.identifier -> tgt.identifier;
  src.status as v -> tgt.status = translate(v, '#CareTeamStatus', 'code');
  src.category -> tgt.category;
  src.name -> tgt.name;
  src.subject -> tgt.subject;
  src.period -> tgt.period;
  src.participant as s -> tgt.participant as t then CareTeamParticipant(s, t);
  src.reasonCode : CodeableConcept -> tgt.reason;
  src.reasonReference : Reference -> tgt.reason;
  src.managingOrganization -> tgt.managingOrganization;
  src.telecom -> tgt.telecom;
  src.note -> tgt.note;
}

group CareTeamParticipant(source src, target tgt) extends BackboneElement {
  src.role -> tgt.role;
  src.member -> tgt.member;
  src.onBehalfOf -> tgt.onBehalfOf;
  src.period : Period -> tgt.coverage;
}