/// url = 'http://hl7.org/fhir/StructureMap/SupplyRequest4Bto5'
/// name = 'SupplyRequest4Bto5'
/// title = 'FML Conversion for SupplyRequest: R4B to R5'
/// status = 'active'

conceptmap "RequestPriority" {
  prefix s = "http://hl7.org/fhir/4.3/request-priority"
  prefix t = "http://hl7.org/fhir/request-priority"

  s:routine - t:routine
  s:urgent - t:urgent
  s:asap - t:asap
  s:stat - t:stat
}

conceptmap "SupplyRequestStatus" {
  prefix s = "http://hl7.org/fhir/4.3/supplyrequest-status"
  prefix t = "http://hl7.org/fhir/supplyrequest-status"

  s:draft - t:draft
  s:active - t:active
  s:suspended - t:suspended
  s:cancelled - t:cancelled
  s:completed - t:completed
  s:"entered-in-error" - t:"entered-in-error"
  s:unknown - t:unknown
}

uses "http://hl7.org/fhir/4.3/StructureDefinition/SupplyRequest" alias SupplyRequestR4B as source
uses "http://hl7.org/fhir/StructureDefinition/SupplyRequest" alias SupplyRequestR5 as target

imports "http://hl7.org/fhir/StructureMap/*4Bto5"

group SupplyRequest(source src : SupplyRequestR4B, target tgt : SupplyRequestR5) extends DomainResource <<type+>> {
  src.identifier -> tgt.identifier;
  src.status as v -> tgt.status = translate(v, '#SupplyRequestStatus', 'code');
  src.category -> tgt.category; // src.basedOn -> tgt.basedOn;
  src.priority as v -> tgt.priority = translate(v, '#RequestPriority', 'code');
  src.item : CodeableConcept -> tgt.item; // src.deliverFor -> tgt.deliverFor;
  src.item : Reference -> tgt.item;
  src.quantity -> tgt.quantity;
  src.parameter as s -> tgt.parameter as t then SupplyRequestParameter(s, t);
  src.occurrence : dateTime -> tgt.occurrence;
  src.occurrence : Period -> tgt.occurrence;
  src.occurrence : Timing -> tgt.occurrence;
  src.authoredOn -> tgt.authoredOn;
  src.requester -> tgt.requester;
  src.supplier -> tgt.supplier;
  src.reasonCode -> tgt.reason;
  src.reasonReference -> tgt.reason;
  src.deliverFrom -> tgt.deliverFrom;
  src.deliverTo -> tgt.deliverTo;
}

group SupplyRequestParameter(source src, target tgt) extends BackboneElement {
  src.code -> tgt.code;
  src.value : CodeableConcept -> tgt.value;
  src.value : Quantity -> tgt.value;
  src.value : Range -> tgt.value;
  src.value : boolean -> tgt.value;
}