FHIR Extensions Pack
5.1.0-ballot1 - Ballot for Release 5.1.0 International flag

This page is part of the FHIR Core Extensions Registry (v5.1.0-ballot: Releases Ballot 4) based on FHIR (HL7® FHIR® Standard) v5.0.0. The current version which supersedes this version is 1.0.0. For a full list of available versions, see the Directory of published versions

StructureMap: FML Conversion for QuestionnaireResponse: R4 to R5

Official URL: http://hl7.org/fhir/StructureMap/QuestionnaireResponse4to5 Version: 5.1.0-ballot1
Standards status: Trial-use Maturity Level: 1 Computable Name: QuestionnaireResponse4to5

FMLConversionforQuestionnaireResponseR4toR5

/// url = 'http://hl7.org/fhir/StructureMap/QuestionnaireResponse4to5'
/// name = 'QuestionnaireResponse4to5'
/// title = 'FML Conversion for QuestionnaireResponse: R4 to R5'
/// status = 'active'

conceptmap "QuestionnaireResponseStatus" {
  prefix s = "http://hl7.org/fhir/4.0/questionnaire-answers-status"
  prefix t = "http://hl7.org/fhir/questionnaire-answers-status"

  s:"in-progress" - t:"in-progress"
  s:completed - t:completed
  s:amended - t:amended
  s:"entered-in-error" - t:"entered-in-error"
  s:stopped - t:stopped
}

uses "http://hl7.org/fhir/4.0/StructureDefinition/QuestionnaireResponse" alias QuestionnaireResponseR4 as source
uses "http://hl7.org/fhir/StructureDefinition/QuestionnaireResponse" alias QuestionnaireResponseR5 as target

imports "http://hl7.org/fhir/StructureMap/*4to5"

group QuestionnaireResponse(source src : QuestionnaireResponseR4, target tgt : QuestionnaireResponseR5) extends DomainResource <<type+>> {
  src.identifier -> tgt.identifier;
  src.basedOn -> tgt.basedOn;
  src.partOf -> tgt.partOf;
  src.questionnaire -> tgt.questionnaire;
  src.status as v -> tgt.status = translate(v, '#QuestionnaireResponseStatus', 'code');
  src.subject -> tgt.subject;
  src.encounter -> tgt.encounter;
  src.authored -> tgt.authored;
  src.author -> tgt.author;
  src.source -> tgt.source;
  src.item as s -> tgt.item as t then QuestionnaireResponseItem(s, t);
}

group QuestionnaireResponseItem(source src, target tgt) extends BackboneElement {
  src.linkId -> tgt.linkId;
  src.definition -> tgt.definition;
  src.text -> tgt.text;
  src.answer as s -> tgt.answer as t then QuestionnaireResponseItemAnswer(s, t);
}

group QuestionnaireResponseItemAnswer(source src, target tgt) extends BackboneElement {
  src.value : boolean -> tgt.value;
  src.value : decimal -> tgt.value;
  src.value : integer -> tgt.value;
  src.value : date -> tgt.value;
  src.value : dateTime -> tgt.value;
  src.value : time -> tgt.value;
  src.value : string -> tgt.value;
  src.value : uri -> tgt.value;
  src.value : Attachment -> tgt.value;
  src.value : Coding -> tgt.value;
  src.value : Quantity -> tgt.value;
  src.value : Reference -> tgt.value;
}