/// url = 'http://hl7.org/fhir/StructureMap/CommunicationRequest4Bto5'
/// name = 'CommunicationRequest4Bto5'
/// title = 'FML Conversion for CommunicationRequest: R4B to R5'
/// status = 'active'

conceptmap "CommunicationPriority" {
  prefix s = "http://hl7.org/fhir/4.3/request-priority"
  prefix t = "http://hl7.org/fhir/request-priority"

  s:routine - t:routine
  s:urgent - t:urgent
  s:asap - t:asap
  s:stat - t:stat
}

conceptmap "CommunicationRequestIntent" {
  prefix s = "http://hl7.org/fhir/4.3/request-intent"
  prefix t = "http://hl7.org/fhir/request-intent"

  s:proposal - t:proposal
  s:plan - t:plan
  s:directive - t:directive
  s:order - t:order
  s:"original-order" - t:"original-order"
  s:"reflex-order" - t:"reflex-order"
  s:"filler-order" - t:"filler-order"
  s:"instance-order" - t:"instance-order"
  s:option - t:option
}

conceptmap "CommunicationRequestStatus" {
  prefix s = "http://hl7.org/fhir/4.3/request-status"
  prefix t = "http://hl7.org/fhir/request-status"

  s:draft - t:draft
  s:active - t:active
  s:"on-hold" - t:"on-hold"
  s:revoked - t:revoked
  s:completed - t:completed
  s:"entered-in-error" - t:"entered-in-error"
  s:unknown - t:unknown
}

uses "http://hl7.org/fhir/4.3/StructureDefinition/CommunicationRequest" alias CommunicationRequestR4B as source
uses "http://hl7.org/fhir/StructureDefinition/CommunicationRequest" alias CommunicationRequestR5 as target

imports "http://hl7.org/fhir/StructureMap/*4Bto5"

group CommunicationRequest(source src : CommunicationRequestR4B, target tgt : CommunicationRequestR5) extends DomainResource <<type+>> {
  src.identifier -> tgt.identifier;
  src.basedOn -> tgt.basedOn;
  src.replaces -> tgt.replaces;
  src.groupIdentifier -> tgt.groupIdentifier;
  src.status as v -> tgt.status = translate(v, '#CommunicationRequestStatus', 'code');
  src.statusReason -> tgt.statusReason;
  src.category -> tgt.category; // src.intent as v -> tgt.intent = translate(v, '#CommunicationRequestIntent', 'code');
  src.priority as v -> tgt.priority = translate(v, '#CommunicationPriority', 'code');
  src.doNotPerform -> tgt.doNotPerform;
  src.medium -> tgt.medium;
  src.subject -> tgt.subject;
  src.about -> tgt.about;
  src.encounter -> tgt.encounter;
  src.payload as s -> tgt.payload as t then CommunicationRequestPayload(s, t);
  src.occurrence : dateTime -> tgt.occurrence;
  src.occurrence : Period -> tgt.occurrence;
  src.authoredOn -> tgt.authoredOn;
  src.requester -> tgt.requester;
  src.recipient -> tgt.recipient;
  src.sender -> tgt.informationProvider;
  src.reasonCode -> tgt.reason;
  src.reasonReference -> tgt.reason;
  src.note -> tgt.note;
}

group CommunicationRequestPayload(source src, target tgt) extends BackboneElement {
  src.content : Attachment -> tgt.content;
  src.content : Reference -> tgt.content;
  src.content : string -> tgt.content;
}