/// url = 'http://hl7.org/fhir/StructureMap/NamingSystem4Bto5'
/// name = 'NamingSystem4Bto5'
/// title = 'FML Conversion for NamingSystem: R4B to R5'
/// status = 'active'

conceptmap "NamingSystemIdentifierType" {
  prefix s = "http://hl7.org/fhir/4.3/namingsystem-identifier-type"
  prefix t = "http://hl7.org/fhir/namingsystem-identifier-type"

  s:oid - t:oid
  s:uuid - t:uuid
  s:uri - t:uri
  s:other - t:other
}

conceptmap "NamingSystemType" {
  prefix s = "http://hl7.org/fhir/4.3/namingsystem-type"
  prefix t = "http://hl7.org/fhir/namingsystem-type"

  s:codesystem - t:codesystem
  s:identifier - t:identifier
  s:root - t:root
}

conceptmap "PublicationStatus" {
  prefix s = "http://hl7.org/fhir/4.3/publication-status"
  prefix t = "http://hl7.org/fhir/publication-status"

  s:draft - t:draft
  s:active - t:active
  s:retired - t:retired
  s:unknown - t:unknown
}

uses "http://hl7.org/fhir/4.3/StructureDefinition/NamingSystem" alias NamingSystemR4B as source
uses "http://hl7.org/fhir/StructureDefinition/NamingSystem" alias NamingSystemR5 as target

imports "http://hl7.org/fhir/StructureMap/*4Bto5"

group NamingSystem(source src : NamingSystemR4B, target tgt : NamingSystemR5) extends DomainResource <<type+>> {
  src.name -> tgt.name; // src.url -> tgt.url;
  src.status as v -> tgt.status = translate(v, '#PublicationStatus', 'code'); // src.title -> tgt.title;
  src.kind as v -> tgt.kind = translate(v, '#NamingSystemType', 'code');
  src.date -> tgt.date; // src.experimental -> tgt.experimental;
  src.publisher -> tgt.publisher;
  src.contact -> tgt.contact;
  src.responsible -> tgt.responsible;
  src.type -> tgt.type;
  src.description -> tgt.description;
  src.useContext -> tgt.useContext;
  src.jurisdiction -> tgt.jurisdiction;
  src.usage -> tgt.usage; // src.purpose -> tgt.purpose;
  src.uniqueId as s -> tgt.uniqueId as t then NamingSystemUniqueId(s, t);
}

group NamingSystemUniqueId(source src, target tgt) extends BackboneElement {
  src.type as v -> tgt.type = translate(v, '#NamingSystemIdentifierType', 'code');
  src.value -> tgt.value;
  src.preferred -> tgt.preferred;
  src.comment -> tgt.comment;
  src.period -> tgt.period;
}