FHIR Extensions Pack
1.0.0 - Working Copy International flag

This page is part of the FHIR Core Extensions Registry (v1.0.0: Releases) based on FHIR v5.0.0. This is the current published version in its permanent home (it will always be available at this URL). For a full list of available versions, see the Directory of published versions

StructureMap: FML Conversion for MessageHeader: R4B to R5

Official URL: http://hl7.org/fhir/StructureMap/MessageHeader4Bto5 Version: 1.0.0
Standards status: Trial-use Maturity Level: 1 Computable Name: MessageHeader4Bto5

FMLConversionforMessageHeaderR4BtoR5

/// url = 'http://hl7.org/fhir/StructureMap/MessageHeader4Bto5'
/// name = 'MessageHeader4Bto5'
/// title = 'FML Conversion for MessageHeader: R4B to R5'
/// status = 'active'

conceptmap "ResponseType" {
  prefix s = "http://hl7.org/fhir/4.3/response-code"
  prefix t = "http://hl7.org/fhir/response-code"

  s:ok - t:ok
  s:"transient-error" - t:"transient-error"
  s:"fatal-error" - t:"fatal-error"
}

uses "http://hl7.org/fhir/4.3/StructureDefinition/MessageHeader" alias MessageHeaderR4B as source
uses "http://hl7.org/fhir/StructureDefinition/MessageHeader" alias MessageHeaderR5 as target

imports "http://hl7.org/fhir/StructureMap/*4Bto5"

group MessageHeader(source src : MessageHeaderR4B, target tgt : MessageHeaderR5) extends DomainResource <<type+>> {
  src.event : Coding -> tgt.event;
  src.event : uri -> tgt.event;
  src.destination as s -> tgt.destination as t then MessageHeaderDestination(s, t);
  src.sender -> tgt.sender;
  src.author -> tgt.author;
  src.source as s -> tgt.source as t then MessageHeaderSource(s, t);
  src.responsible -> tgt.responsible;
  src.reason -> tgt.reason;
  src.response as s -> tgt.response as t then MessageHeaderResponse(s, t);
  src.focus -> tgt.focus;
  src.definition -> tgt.definition;
}

group MessageHeaderDestination(source src, target tgt) extends BackboneElement {
  src.endpoint : url -> tgt.endpoint;
  src.name -> tgt.name;
  src.target -> tgt.target;
  src.receiver -> tgt.receiver;
}

group MessageHeaderSource(source src, target tgt) extends BackboneElement {
  src.endpoint : url -> tgt.endpoint;
  src.name -> tgt.name;
  src.software -> tgt.software;
  src.version -> tgt.version;
  src.contact -> tgt.contact;
}

group MessageHeaderResponse(source src, target tgt) extends BackboneElement {
  src.identifier as s ->  tgt.identifier = create('Identifier') as t,  t.value = s;
  src.code as v -> tgt.code = translate(v, '#ResponseType', 'code');
  src.details -> tgt.details;
}