/// url = 'http://hl7.org/fhir/StructureMap/ImplementationGuide4Bto5'
/// name = 'ImplementationGuide4Bto5'
/// title = 'FML Conversion for ImplementationGuide: R4B to R5'
/// status = 'active'

conceptmap "GuidePageGeneration" {
  prefix s = "http://hl7.org/fhir/4.3/guide-page-generation"
  prefix t = "http://hl7.org/fhir/guide-page-generation"

  s:html - t:html
  s:markdown - t:markdown
  s:xml - t:xml
  s:generated - t:generated
}

conceptmap "PublicationStatus" {
  prefix s = "http://hl7.org/fhir/4.3/publication-status"
  prefix t = "http://hl7.org/fhir/publication-status"

  s:draft - t:draft
  s:active - t:active
  s:retired - t:retired
  s:unknown - t:unknown
}

conceptmap "SPDXLicense" {
  prefix s = "http://hl7.org/fhir/4.3/spdx-license"
  prefix t = "http://hl7.org/fhir/spdx-license"

  s:"not-open-source" - t:"not-open-source"
  s:"0BSD" - t:"0BSD"
  s:AAL - t:AAL
  s:Abstyles - t:Abstyles
  s:"Adobe-2006" - t:"Adobe-2006"
  s:"Adobe-Glyph" - t:"Adobe-Glyph"
  s:ADSL - t:ADSL
  s:"AFL-1.1" - t:"AFL-1.1"
  s:"AFL-1.2" - t:"AFL-1.2"
  s:"AFL-2.0" - t:"AFL-2.0"
  s:"AFL-2.1" - t:"AFL-2.1"
  s:"AFL-3.0" - t:"AFL-3.0"
  s:Afmparse - t:Afmparse
  s:"AGPL-1.0-only" - t:"AGPL-1.0-only"
  s:"AGPL-1.0-or-later" - t:"AGPL-1.0-or-later"
  s:"AGPL-3.0-only" - t:"AGPL-3.0-only"
  s:"AGPL-3.0-or-later" - t:"AGPL-3.0-or-later"
  s:Aladdin - t:Aladdin
  s:AMDPLPA - t:AMDPLPA
}

uses "http://hl7.org/fhir/4.3/StructureDefinition/ImplementationGuide" alias ImplementationGuideR4B as source
uses "http://hl7.org/fhir/StructureDefinition/ImplementationGuide" alias ImplementationGuideR5 as target

imports "http://hl7.org/fhir/StructureMap/*4Bto5"

group ImplementationGuide(source src : ImplementationGuideR4B, target tgt : ImplementationGuideR5) extends DomainResource <<type+>> {
  src.url -> tgt.url;
  src.version -> tgt.version; // src.identifier -> tgt.identifier;
  src.name -> tgt.name; // src.versionAlgorithm : string -> tgt.versionAlgorithm;
  src.title -> tgt.title;
  src.status as v -> tgt.status = translate(v, '#PublicationStatus', 'code');
  src.experimental -> tgt.experimental;
  src.date -> tgt.date;
  src.publisher -> tgt.publisher;
  src.contact -> tgt.contact;
  src.description -> tgt.description;
  src.useContext -> tgt.useContext;
  src.jurisdiction -> tgt.jurisdiction;
  src.copyright -> tgt.copyright; // src.purpose -> tgt.purpose;
  src.packageId -> tgt.packageId; // src.copyrightLabel -> tgt.copyrightLabel;
  src.license as v -> tgt.license = translate(v, '#SPDXLicense', 'code');
  src.fhirVersion -> tgt.fhirVersion;
  src.dependsOn as s -> tgt.dependsOn as t then ImplementationGuideDependsOn(s, t);
  src.global as s -> tgt.global as t then ImplementationGuideGlobal(s, t);
  src.definition as s -> tgt.definition as t then ImplementationGuideDefinition(s, t);
  src.manifest as s -> tgt.manifest as t then ImplementationGuideManifest(s, t);
}

group ImplementationGuideDependsOn(source src, target tgt) extends BackboneElement {
  src.uri -> tgt.uri;
  src.packageId -> tgt.packageId;
  src.version -> tgt.version;
}

group ImplementationGuideGlobal(source src, target tgt) extends BackboneElement {
  src.type -> tgt.type;
  src.profile -> tgt.profile;
}

group ImplementationGuideDefinition(source src, target tgt) extends BackboneElement {
  src.grouping as s -> tgt.grouping as t then ImplementationGuideDefinitionGrouping(s, t);
  src.resource as s -> tgt.resource as t then ImplementationGuideDefinitionResource(s, t);
  src.page as s -> tgt.page as t then ImplementationGuideDefinitionPage(s, t);
  src.parameter as s -> tgt.parameter as t then ImplementationGuideDefinitionParameter(s, t);
  src.template as s -> tgt.template as t then ImplementationGuideDefinitionTemplate(s, t);
}

group ImplementationGuideDefinitionGrouping(source src, target tgt) extends BackboneElement {
  src.name -> tgt.name;
  src.description -> tgt.description;
}

group ImplementationGuideDefinitionResource(source src, target tgt) extends BackboneElement {
  src.reference -> tgt.reference;
  src.fhirVersion as v -> tgt.fhirVersion = translate(v, '#FHIRVersion', 'code');
  src.name -> tgt.name;
  src.description -> tgt.description;
  src.example : boolean -> tgt.isExample;
  src.example : canonical -> tgt.profile;
  src.groupingId -> tgt.groupingId;
}

group ImplementationGuideDefinitionPage(source src, target tgt) extends BackboneElement {
  src.name : url -> tgt.source;
  src.name : url -> tgt.name; // src.name : Reference -> tgt.source; - this wasn't used?
  src.title -> tgt.title;
  src.generation as v -> tgt.generation = translate(v, '#GuidePageGeneration', 'code');
  src.page as s -> tgt.page as t then ImplementationGuideDefinitionPage(s, t);
}

group ImplementationGuideDefinitionParameter(source src, target tgt) extends BackboneElement {
  src.code as s ->  tgt.code as t,  t.system = 'http://hl7.org/fhir/guide-parameter-code',  t.code = s;
  src.value -> tgt.value;
}

group ImplementationGuideDefinitionTemplate(source src, target tgt) extends BackboneElement {
  src.code -> tgt.code;
  src.source -> tgt.source;
  src.scope -> tgt.scope;
}

group ImplementationGuideManifest(source src, target tgt) extends BackboneElement {
  src.rendering -> tgt.rendering;
  src.resource as s -> tgt.resource as t then ImplementationGuideManifestResource(s, t);
  src.page as s -> tgt.page as t then ImplementationGuideManifestPage(s, t);
  src.image -> tgt.image;
  src.other -> tgt.other;
}

group ImplementationGuideManifestResource(source src, target tgt) extends BackboneElement {
  src.reference -> tgt.reference;
  src.example : boolean -> tgt.isExample;
  src.example : canonical -> tgt.profile;
  src.relativePath -> tgt.relativePath;
}

group ImplementationGuideManifestPage(source src, target tgt) extends BackboneElement {
  src.name -> tgt.name;
  src.title -> tgt.title;
  src.anchor -> tgt.anchor;
}