/// url = 'http://hl7.org/fhir/StructureMap/Consent5to4'
/// name = 'Consent5to4'
/// title = 'FML Conversion for Consent: R5 to R4'
/// status = 'active'

conceptmap "ConsentDataMeaning" {
  prefix s = "http://hl7.org/fhir/consent-data-meaning"
  prefix t = "http://hl7.org/fhir/4.0/consent-data-meaning"

  s:instance - t:instance
  s:related - t:related
  s:dependents - t:dependents
  s:authoredby - t:authoredby
}

conceptmap "ConsentProvisionType" {
  prefix s = "http://hl7.org/fhir/consent-provision-type"
  prefix t = "http://hl7.org/fhir/4.0/consent-provision-type"

  s:deny - t:deny
  s:permit - t:permit
}

conceptmap "ConsentState" {
  prefix s = "http://hl7.org/fhir/consent-state-codes"
  prefix t = "http://hl7.org/fhir/4.0/consent-state-codes"

  s:draft - t:draft
  s:active - t:active
  s:inactive - t:inactive
  s:"not-done" - t:rejected
  s:"entered-in-error" - t:"entered-in-error"
  s:unknown - t:proposed
}

uses "http://hl7.org/fhir/StructureDefinition/Consent" alias ConsentR5 as source
uses "http://hl7.org/fhir/4.0/StructureDefinition/Consent" alias ConsentR4 as target

imports "http://hl7.org/fhir/StructureMap/*5to4"

group Consent(source src : ConsentR5, target tgt : ConsentR4) extends DomainResource <<type+>> {
  src.identifier -> tgt.identifier;
  src.status as v -> tgt.status = translate(v, '#ConsentState', 'code');
  src.category -> tgt.category;
  src.subject -> tgt.patient;
  src.date -> tgt.dateTime;
  src.grantee -> tgt.performer; // src.period -> tgt.period;
  src.sourceAttachment -> tgt.source; // src.manager -> tgt.manager;
  src.sourceReference -> tgt.source;
  src.regulatoryBasis -> tgt.policyRule;
  src.policyBasis as s ->  tgt.policy as t,  t.uri = s.url;
  src.verification as s -> tgt.verification as t then ConsentVerification(s, t); // src.policyText -> tgt.policyText;
  src.provision as s -> tgt.provision as t then ConsentProvision(s, t); // src.decision as v -> tgt.decision = translate(v, '#ConsentProvisionType', 'code');
}

// group ConsentPolicyBasis(source src, target tgt) extends BackboneElement {
// src.reference -> tgt.reference;
// src.url -> tgt.url;
// }
group ConsentVerification(source src, target tgt) extends BackboneElement {
  src.verified -> tgt.verified;
  src.verifiedWith -> tgt.verifiedWith; // src.verificationType -> tgt.verificationType;
  src.verificationDate -> tgt.verificationDate;
}

group ConsentProvision(source src, target tgt) extends BackboneElement {
  src.period -> tgt.period;
  src.actor as s -> tgt.actor as t then ConsentProvisionActor(s, t);
  src.action -> tgt.action;
  src.securityLabel -> tgt.securityLabel;
  src.purpose -> tgt.purpose;
  src.documentType -> tgt.class;
  src.code -> tgt.code; // src.resourceType -> tgt.resourceType;
  src.dataPeriod -> tgt.dataPeriod;
  src.data as s -> tgt.data as t then ConsentProvisionData(s, t);
}

group ConsentProvisionActor(source src, target tgt) extends BackboneElement {
  src.role -> tgt.role;
  src.reference -> tgt.reference;
}

group ConsentProvisionData(source src, target tgt) extends BackboneElement {
  src.meaning as v -> tgt.meaning = translate(v, '#ConsentDataMeaning', 'code');
  src.reference -> tgt.reference;
}